如何删除SAS中两个字符串之间的所有出现次数（0或多个）

Question

I am trying to parse a .json file into SAS. In order to deal with lists in the .json file, I would like to remove all commas from between [item1, item2, item3, .... itemn], but keep the commas that are not within [].

I think I should be able to do this using prxchange regular expression...I can get it working for a two item list, but can't figure out how to alter it to work with lists of different amounts.

newvariable=prxchange('s/(\\[\\w+),(\\w+\\])/$1 $2',-1,oldvariable);

Examples:

oldvariable = "{"hospital": "NOP", "drugs": ["penicillin", "ampicillin", "cephalosporin"]}" 
newvariable = "{"hospital": "NOP", "drugs": ["penicillin" "ampicillin" "cephalosporin"]}" 

oldvariable = "{"hospital": "KOP", "drugs": ["tetracycline"]}" 
newvariable = "{"hospital": "KOP", "drugs": ["tetracycline"]}" 

Maybe there is a better way to approach this...

Answer 1

Sometimes the easiest way to handle a regex is to break it into steps. In this case, first get the array out, then replace the commas with spaces:

data _null_;
oldvariable = '{"hospital": "NOP", "drugs": ["penicillin", "ampicillin", "cephalosporin"]}';
arrayExpr=prxparse( '/\[[^]]+\]/' );
call prxsubstr( arrayExpr, oldvariable, position, length );
put position length;
newvariable=cat(
    substr( oldvariable, 1, position - 1 ),
    prxchange( 's/, / /', -1, substr( oldvariable, position, length ) ),
    substr( oldvariable, position + length )
);
put newvariable;
run;

Your original regex had some problems as well. Of the many regex-helper sites this one is my favorite .

Answer 2

You can take advantage of SAS's DSD option (which allows you to use quotation marks to ignore embedded delimiters) if you do a smaller prxchange, similar to Leo's suggestion.

data have;
infile datalines dlm=',' dsd;
input @;
_prx = prxparse('s~\[([0-9,]*?)\]~"$1"~io');
_prxm = prxmatch(_prx,_infile_);
if _prxm then call prxchange(_prx,-1,_infile_);
_test_=_infile_;
input a b $ c d $;
datalines;
1,Hello,2,3
2,Goodbye,3,[4,5,6]
;;;;
run;

In your case I'm not sure if double quotation marks would work, since they have a meaning in JSON, but you could use single quotes just as well.