Perl grep总是返回列表上下文中的匹配数

Question

I have a script with the lists

@names = ();
@x = ();

Both lists are filled in parallel with data, therefore, in the end I have two lists with name and x-value for each element at the same index. Note, there are more than one element having the same x-value.

I want to have all elements having a specific x-value with the code

foreach my $x (0..4) {      
    my @ind = grep { $x[$_] == $x } 0..$#names;
    print @ind . "\n";
}

However, the output is

17
17
8
4

which is exactly the number of elements having x=0, x=1, ...

I'm wondering since grep in a list context should return me a list with the matches (here, the indizes of matching elements).

What am I doing wrong here?

Best regards.

Answer 1

Your problem is this line:

print @ind . "\n";

When you use the concatenation operator . you put both parameters into scalar context, and in scalar context, an array returns its size, not its content.

What you want is to use the comma operator instead:

print @ind , "\n";

Or better yet, use the feature say :

say @ind;

In case what you actually want is to print the numbers in a line, separated by space:

say "@ind";

Or in case you want to print them separated by newlines:

say for @ind;

In all the above, say can of course be replaced by print with a newline at the end.

Answer 2

You should use an array of hashes to store the data as one unit. Do this where you populate @x and @names . (Assuming the x-value is in $x and the name is in $name .)

push @data, {
    name => $name,
    x    => $x,
};

To retrieve a name at index $i : $data[$i]{name}

To retrieve a x-value at index $i : $data[$i]{x}

To iterate over the array:

for my $item_ref ( @data ){
    my $name = $item_ref->{name};
    my $x    = $item_ref->{x};
    # do something
}