使用XSLT 1.0重命名并添加新元素

Question

I have a following issue when trying to modify my XML file. I'm trying to apply three transformations to the input below:

<sheet>
<row>
    <column_1>11</column_1>
    <column_2></column_2>
    <column_3></column_3>
</row>
<row>
    <column_1></column_1>
    <column_2></column_2>
    <column_3></column_3>
</row>
<row>
    <column_1></column_1>
    <column_2></column_2>
    <column_3></column_3>
</row>
</sheet>

1) shift/rename columns by 4, I was able to do that using following XSLT:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
<xsl:output indent="yes"/>
<xsl:template match="node() | @*">
    <xsl:copy>
        <xsl:apply-templates select="node() | @*"/>
    </xsl:copy>
</xsl:template>
<xsl:template match="row/*">
    <xsl:element name="column_{substring(name(),8,string-length(name())-7)+4}">
        <xsl:apply-templates select="@* | node()" />
    </xsl:element>
</xsl:stylesheet>

output received:

<sheet>
<row>
    <column_5>11</column_5>
    <column_6></column_6>
    <column_7></column_7>
</row>
<row>
    <column_5></column_5>
    <column_6></column_6>
    <column_7></column_7>
</row>
<row>
    <column_5></column_5>
    <column_6></column_6>
    <column_7></column_7>
</row>
</sheet>

2) add elements before already existing ones so below output is received: I have to say I'm lost here as have no ideas how to make it work.

<sheet>
<row>
    <column_1></column_1>
    <column_2></column_2>
    <column_3></column_3>
    <column_4></column_4>
    <column_5>11</column_5>
    <column_6></column_6>
    <column_7></column_7>
</row>
<row>
    <column_1></column_1>
    <column_2></column_2>
    <column_3></column_3>
    <column_4></column_4>
    <column_5></column_5>
    <column_6></column_6>
    <column_7></column_7>
</row>
<row>
    <column_1></column_1>
    <column_2></column_2>
    <column_3></column_3>
    <column_4></column_4>
    <column_5></column_5>
    <column_6></column_6>
    <column_7></column_7>
</row>
</sheet>

3) incorporate following XSLT I was using to propagate data, it works if its applied on its own but when merged with point 1) i got no result only pint 1 is being applied

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
<xsl:output indent="yes"/>
<xsl:template match="node() | @*">
<xsl:copy>
  <xsl:apply-templates select="node() | @*"/>
</xsl:copy>
</xsl:template>
<xsl:template match="column_5">
<xsl:copy>
  <xsl:choose>
    <xsl:when test=".=''">
      <xsl:value-of select="preceding::column_5[. != ''][1]"/>
    </xsl:when>
    <xsl:otherwise>
      <xsl:apply-templates select="node() | @*"/>
    </xsl:otherwise>
  </xsl:choose>
</xsl:copy>
</xsl:template>
</xsl:stylesheet>

My expected result would be:

<sheet>
<row>
    <column_1></column_1>
    <column_2></column_2>
    <column_3></column_3>
    <column_4></column_4>
    <column_5>11</column_5>
    <column_6></column_6>
    <column_7></column_7>
</row>
<row>
    <column_1></column_1>
    <column_2></column_2>
    <column_3></column_3>
    <column_4></column_4>
    <column_5>11</column_5>
    <column_6></column_6>
    <column_7></column_7>
</row>
<row>
    <column_1></column_1>
    <column_2></column_2>
    <column_3></column_3>
    <column_4></column_4>
    <column_5>11</column_5>
    <column_6></column_6>
    <column_7></column_7>
</row>
</sheet>

Thanks, Lehu

Answer 1

It's not pretty, but here you go.

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output indent="yes" />

  <xsl:template match="node() | @*">
    <xsl:copy>
      <xsl:apply-templates select="node() | @*"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="row">
    <xsl:copy>
      <column_1 />
      <column_2 />
      <column_3 />
      <column_4 />
      <xsl:apply-templates select="*" />
    </xsl:copy>
  </xsl:template>

  <xsl:template match="row/*">
    <xsl:element name="column_{substring-after(name(), 'column_') + 4}">
      <xsl:apply-templates select="@* | node()" />
    </xsl:element>
  </xsl:template>

  <xsl:template match="column_1[. = '']">
    <column_5>
      <xsl:value-of select="preceding::column_1[. != ''][1]/text()" />
    </column_5>
  </xsl:template>

</xsl:stylesheet>