如何检查字符串是否包含 VBScript 中的十六进制值？

Question

Is there a function in VBScript to check if a string contains a valid hexadecimal value?

For Example:

Dim x : x = IsHexadecimal("2AF3") 'x = True

Dim y : y = IsHexadecimal("X2M3") 'y = False

Answer 1

You could use a regular expression, as others have already suggested:

Function IsHexadecimal(ByVal v)
  Set re = New RegExp
  re.Pattern = "^[a-f0-9]+$"
  re.IgnoreCase = True
  IsHexadecimal = re.Test(v)
End Function

Another solution (with a little more hack value):

Function IsHexadecimal(ByVal v)
  On Error Resume Next
  Dim i : i = CLng("&h" & v)
  IsHexadecimal = Not IsEmpty(i)
  On Error Goto 0
End Function

Answer 2

I realise this is an old thread, but here is my solution. It is based on vbscript's built-in IsNumeric function that can identify a hex string provided it is preceded by &h

function is_hex(str_hex)
  is_hex = IsNumeric("&h" & str_hex)
end function

Answer 3

Not sure if such a function is built-in to vbscript, but you could roll your own with something like this:

function isHexadecimal(s as string)
  Dim i as integer, c as string, R as boolean
  R=true
  for i=1 to length(s)
    c=mid(S,i,1)
    if instr("0123456789ABCDEFabcdef", c)<=0 then R=false
  next i
  sHexadecimal=R
end function

Answer 4

You could use RegEx, like this:

'Prepare a regular expression object
Set myRegExp = New RegExp
myRegExp.IgnoreCase = True
myRegExp.Global = True
myRegExp.Pattern = "\A\b[0-9a-fA-F]+\b\Z"


' Pop up a message box for each match
Set myMatches = myRegExp.Execute(subjectString)
For Each myMatch in myMatches
  msgbox myMatch.Value, 0, "Found Match"
Next

Check this link http://www.regular-expressions.info/vbscript.html

Hope it helps ^_^

Answer 5

Same as Ansgar Wiechers' answer, but the regex needs to be af, not ae.

Function IsHexadecimal(ByVal v)
  Set re = New RegExp
  re.Pattern = "^[a-f0-9]+$"
  re.IgnoreCase = True
  IsHexadecimal = re.Test(v)
End Function

Answer 6

Either write a function that implements:

For Each character In input
    IF character Is Not In "0-9A-Za-z"
       Exit with False
    End If
Next
Exit with True

or use a RegExp.Test() with the .Pattern "[^0-9A-Za-z]".

In both cases, checking the length of the input may be a good idea.

Answer 7

I wrote a specific function.

The following code works fine:

Function IsHexadecimal(ByVal input_string)
    Dim b : b = False   
    Dim s_length : s_length = Len(input_string)
    Dim char 
    For i = 1 To s_length
        char = Asc(Mid(input_string, i, 1))
        If (char > 47 And char < 58) Or _
            (char > 64 And char < 71) Or _
            (char > 96 And char < 103) Then
            b = True
        Else
            b = False
            Exit For
        End If
    Next
    IsHexadecimal = b
End Function

Answer 8

Maybe not the most optimized but it is easy and it works fairly well:

Private Function IsHexadecimal(Text2Verify As String) As Boolean
    Dim i As Integer
    For i = 1 To Len(Text2Verify)
        If Not Mid(Text2Verify, i, 1) Like "*[*0*1*2*3*4*5*6*7*8*9*A*B*C*D*E*F*a*b*c*d*e*f*]*" Then
            IsHexadecimal = False
            Exit Function
        End If
    Next i
    IsHexadecimal = True
End Function