无法加载Qt5 / cmake Project中Qt资源文件中指定的图像

Question

I just started a Qt5 project using cmake as build system. So far this working quite well but I have problems with an icon that I want to load from a qrc file.

Project structure:

CMakeLists.txt
-- icons/
   CMakeLists.txt
   icons.qrc
   locked.png
-- src/
   CMakeLists.txt
   source files...

Top Level CMakeLists.txt:

cmake_minimum_required(VERSION 2.8.11) #2.8.11 provides an easy way to build with qt5
project(fluchOmat)

# Find includes in corresponding build directories
set(CMAKE_INCLUDE_CURRENT_DIR ON)
# Instruct CMake to run moc automatically when needed.
set(CMAKE_AUTOMOC ON)

# Find the QtWidgets library. This has dependencies on QtGui and QtCore!
find_package(Qt5Widgets REQUIRED)
# Find the QtMultimedia module
find_package(Qt5Multimedia REQUIRED)

add_subdirectory(icons)
add_subdirectory(src)

CMakeLists.txt in icons/

set(RESOURCE
    ${CMAKE_CURRENT_SOURCE_DIR}/icons.qrc
)

qt5_add_resources(RESOURCE_ADDED ${RESOURCE})

icons.qrc in icons/

<RCC>
    <qresource prefix="/">
        <file alias="locked">locked.png</file>
    </qresource>
</RCC>

CMakeLists.txt in src/ (important part)

add_executable(fluchOmat ${SOURCES} ${HEADERS} ${fluchOmat_FORMS} ${RESOURCES_ADDED})

Some sample code

QPixmap pm(":/locked.png");
qDebug("Width: " + pm.width());

returns nothing, so obviously this didn't work.

There aren't many resources out there for Qt5 and cmake. Can anyone help me with this? Is this a cmake problem? For example I am not sure if qt5_add_resources is at the right location. Is my qrc file wrong?

Any help is greatly appreciated!

Answer 1

The problem lies in the scoping rules of CMake. each add_subdirectory call creates its own scope. Variables declared in such a subdirectory aren't automatically populated up to the parent scope.

So the problem is that while RESOURCE_ADDED contains a valid path in the scope of icons/CMakeLists.txt, it doesn't in the root CMakeLists.txt and hence it is an empty variable by the time you use it in src/CMakeLists.txt.

To raise the variable up a scope, in icons/CMakeLists.txt you can do:

qt5_add_resources(RESOURCE_ADDED ${RESOURCE})
set(RESOURCE_ADDED ${RESOURCE_ADDED} PARENT_SCOPE)

There's another slight problem now though!

While this will contain a valid value in src/CMakeLists.txt, it points to a file which doesn't yet exist. The qt5_add_resources function must apply the GENERATED source file property to the variable. This property is not carried forward to the variable set in the parent scope.

Since add_executable expects files to exist by default, you'll need to reapply the GENERATED property to the variable in the parent scope. You can do this eg in the src/CMakeLists.txt like this:

set_source_files_properties(${RESOURCE_ADDED} PROPERTIES GENERATED ON)
add_executable(fluchOmat ... ${RESOURCE_ADDED})

I'm not sure if the qt5_add_resources adds any other properties - if so, you'd maybe also have to reapply these.

I'd guess the easiest way to avoid this would be to not use add_subdirectory(icons) , and instead just move all the Qt-related CMake code to src/CMakeLists.txt:

set(RESOURCE ${CMAKE_SOURCE_DIR}/icons/icons.qrc)
qt5_add_resources(RESOURCE_ADDED ${RESOURCE})
add_executable(fluchOmat ... ${RESOURCE_ADDED})