如果未定义数组中的所有元素，如何在Perl中对数组进行排序？

Question

How do I sort an array if not all of the elements in the array are defined?

my @names;
$names[0]  = "andrei";
$names[1]  = "serghei";
$names[7]  = "valerii";
$names[10] = "alexandr";

@names = sort @names; # aint working.

I apologize guys, I just don't get how to post questions here properly. I tried the FAQ, I just don't get it.

Answer 1

undef will is lower than any non-empty string, this is why it get's sorted at the beginning. What you probably want is a "cleaned" result array with all undef elements removed? If so, here:

#!/usr/bin/perl

use strict;
use Data::Dumper;

my @names;
$names[1] = 'alpha';
$names[3] = 'gamma';
$names[10] = 'beta';
@names = sort grep { defined } @names;

print Dumper(\@names);

# $VAR1 = [
#   'alpha',
#   'beta',
#   'gamma'
# ];

Answer 2

To get rid of the undefined elements and sort the rest:

sort grep defined, @names

To place the undefined elements at the start:

sort { !defined($a) && !defined($b) ? 0
     : !defined($a) ? -1
     : !defined($b) ? +1
     : $a cmp $b
} @names

To place the undefined elements at the end:

sort { !defined($a) && !defined($b) ? 0
     : !defined($a) ? +1
     : !defined($b) ? -1
     : $a cmp $b
} @names

Answer 3

An easy one-liner to print your array including gaps:

print join "\n", @names;

Or if you want to put 'undefined' values in:

print join "\n", map {$_ || "undef"} @names;

If you want to trim out the undefined values, use grep as ukautz suggested in his answer.

print join "\n", grep {defined} @names;

You can use the same approach to get the valid indices:

@idx = grep {defined $names[$_]} keys @names;

The above can be used if you wanted to sort the defined values and then insert them back in the defined positions. Sort of like an in-place sort.

@sorted = grep {defined} sort @names;
map {$names[$idx[$_]] = $sorted[$_]} keys @sorted;

Answer 4

use strict;
use warnings;
use autodie;
use feature qw(say);

my @names;
$names[0]  = "andrei";
$names[1]  = "serghei";
$names[7]  = "valerii";
$names[10] = "alexandr";

@names = sort grep { defined } @names;

for my $name ( @names ) {
    say $name;
}

The grep { defined } takes @names and removes all the undefined values from @names .

If you don't want to remove the undefined stuff, you can do this:

#! /usr/bin/env perl
#
use strict;
use warnings;
use autodie;
use feature qw(say);

my @names;
$names[0]  = "andrei";
$names[1]  = "serghei";
$names[7]  = "valerii";
$names[10] = "alexandr";

no warnings qw(uninitialized);
@names = sort @names;
use warnings qw(uninitialized);

for my $name ( @names ) {
    say $name if defined $name;;
}

The no warnings qw(initialized); will turn off uninitialized warnings. I know that I'll run into trouble with unitialized warnging with sort , so I simply turn off the uninitialized warnings, and turn them right back on right after the sort .