xsl-fo中的嵌套循环

Question

    <years>
        <year yearValue="2012">
            <months>
                <month monthValue="4">
                    <projectElements>
                        <projectElement projectElementValue="756" />
                    </projectElements>
                </month>
                <month monthValue="8">
                    <projectElements>
                        <projectElement projectElementValue="12345" />
                    </projectElements>
                </month>
            </months>
        </year>
        <year yearValue="2013">
            <months>
                <month monthValue="8">
                    <projectElements>
                        <projectElement projectElementValue="ffff" />
                        <projectElement projectElementValue="12345" />
                    </projectElements>
                </month>
            </months>
        </year>
    </years>

I have an xml file as seen above. In my .fo file I want a loop like this:

for every year in years, for every month in months for every projectElement in projectElements

year = yearValue month = monthValue projectElement = projectElementValue

This does not work:

<xsl:for-each select="activityExport/years/year">
<xsl:for-each select="activityExport/years/year/months/month">

I get zero results.

This returns 4 loops as expected, but then I loose the month and year info:

<xsl:for-each select="activityExport/years/year/months/month/projectElements/projectElement">

Thanks for your help

Answer 1

Your second <xsl:for-each> has a relative XPath expression that is attempting to address activityExport elements that are children of the current year (which do not exist, so they produce nothing).

If you correct the XPath to look relative to the context node, which is the year element, you will get the expected number of iterations.

Then you can solve the second issue of how to access the year and month values from inside the inner-most <xsl:for-each> . Below are two examples of how you can do that:

1.) In order to use the nested <xsl:for-each> and be able to retain a reference to context of the context node from the outer <xsl:for-each> you can set a variable and reference the variable from inside the nested <xsl:for-each> statements:

<xsl:for-each select="years/year">
  <xsl:variable name="yearValue" select="@yearValue"/>
  <xsl:for-each select="months/month">
    <xsl:variable name="monthValue" select="@monthValue"/>
    <xsl:for-each select="projectElements/projectElement">
      <xsl:value-of select="concat('year = ', $yearValue, 
                                   ' month = ', $monthValue, 
                                   ' projectElement = ', @projectElementValue, 
                                   '&#xA;')"/>
    </xsl:for-each>
  </xsl:for-each>
</xsl:for-each>

2.) Avoid the use of variables and address the ancestor nodes from the context node of the inner-most <xsl:for-each> :

<xsl:for-each select="years/year">
  <xsl:for-each select="months/month">
     <xsl:for-each select="projectElements/projectElement">
         <xsl:value-of select="concat('year = ', ancestor::year/@yearValue, 
                                      ' month = ', ancestor::month/@monthValue, 
                                      ' projectlement = ', @projectElementValue, 
                                      '&#xA;')"/>
     </xsl:for-each>
  </xsl:for-each>
</xsl:for-each>

3.) Use a single <xsl:for-each>

<xsl:for-each select="years/year/
                       months/month/
                        projectElements/projectElement">
    <xsl:value-of select="concat('year = ', ancestor::year/@yearValue, 
                                 ' month = ', ancestor::month/@monthValue, 
                                 ' projectlement = ', @projectElementValue, 
                                 '&#xA;')"/>
</xsl:for-each>

---

You could also eliminate <xsl:for-each> and use <xsl:apply-templates> :

<xsl:apply-templates select="years/year/months/month/projectElements/projectElement"/>

with a template defined

<xsl:template match="projectElement">
   <xsl:value-of select="concat('year = ', ancestor::year/@yearValue, 
                                ' month = ', ancestor::month/@monthValue, 
                                ' projectElement = ', @projectElementValue, 
                                '&#xA;')"/>
</xsl:template>

Each of the examples produces the following output from the sample XML:

year = 2012 month = 4 projectElement = 756
year = 2012 month = 8 projectElement = 12345
year = 2013 month = 8 projectElement = ffff
year = 2013 month = 8 projectElement = 12345

Answer 2

外循环的上下文会产生“ activityExport /年/年”，因此内循环应相对于此路径（或月/月）。