SQL After Update触发器似乎阻止插入工作

Question

I'm new to triggers and I can't seem to find an answer to this question.

I need to insert calculated rows in a table and have no access to the application source code. I thought a work around might be to create a trigger on the table to calculate the values based on the inserted values then insert them into the table, though I'm not real sure how this works.

I have the following trigger, it works for update, but doesn't work for insert. If I remove "INSERT" in "FOR INSERT, UPDATE" it will insert the account_id field (which is the only non-null field), but not the rest. If I leave "INSERT" in, it will not insert any of the fields.

How can I make this work for both Inserts and updates?

ALTER TRIGGER [dbo].[SelfCalFieldsTrigger]
ON [dbo].[dynTable]
FOR INSERT, UPDATE
AS
BEGIN

Declare @acctID uniqueidentifier
Declare @invDiscPremPerc decimal(9,6)
Declare @investorSRP decimal(9,6)
Declare @purchWireAmt decimal(11,2)

set @acctID = (Select account_id from inserted) 

set @invDiscPremPerc = (Select Coalesce(INVESTOR_DISC_PREM_DOLLAR, 0)/
Coalesce(INVESTOR_PRIN_BAL_PURCHASED, 0)*100 from inserted)


set @investorSRP = (Select Coalesce(INVESTOR_SRP_PREM_DOLLAR, 0)/
Coalesce(INVESTOR_PRIN_BAL_PURCHASED, 0)*100 from inserted)


set @purchWireAmt = (Select Coalesce(INVESTOR_PRIN_BAL_PURCHASED, 0)-
Coalesce(INVESTOR_ADMIN_FEE, 0)-
Coalesce(INVESTOR_WIRE_FEE, 0)- Coalesce(INVESTOR_FLOOD_FEE, 0)-
Coalesce(INVESTOR_TAX_SERVICE_FEE, 0) - Coalesce(INVESTOR_OTHER_FEE, 0) from     
inserted)


UPDATE [dbo].dynTable]
set INVESTOR_DISC_PREM_PERCENT = @invDiscPremPerc,
INVESTOR_SRP = @investorSRP,
PURCHASE_WIRE_AMOUNT = @purchWireAmt
Where [dbo].[dynTable].Account_ID = @acctID

END

Answer 1

You need to change the logic of your trigger. Right now, you are assuming that there is only one row inserted or updated, but that's not how it works. INSERTED is a pseudo table that contains all rows inserted or updated. So, try this instead:

ALTER TRIGGER [dbo].[SelfCalFieldsTrigger]
ON [dbo].[dynTable]
FOR INSERT, UPDATE
AS
BEGIN

    UPDATE A
    SET INVESTOR_DISC_PREM_PERCENT = ISNULL(B.INVESTOR_DISC_PREM_DOLLAR / 
                                            NULLIF(B.INVESTOR_PRIN_BAL_PURCHASED,0)*100,0),
    INVESTOR_SRP = ISNULL(B.INVESTOR_SRP_PREM_DOLLAR / 
                          NULLIF(B.INVESTOR_PRIN_BAL_PURCHASED,0)*100,0),
    PURCHASE_WIRE_AMOUNT =  COALESCE(B.INVESTOR_PRIN_BAL_PURCHASED, 0)-
                            COALESCE(B.INVESTOR_ADMIN_FEE, 0)-
                            COALESCE(B.INVESTOR_WIRE_FEE, 0)- 
                            COALESCE(B.INVESTOR_FLOOD_FEE, 0)-
                            COALESCE(B.INVESTOR_TAX_SERVICE_FEE, 0)- 
                            COALESCE(B.INVESTOR_OTHER_FEE, 0)
    FROM [dbo].[dynTable] A
    INNER JOIN INSERTED B
        ON A.Account_ID = B.Account_ID

END

Answer 2

I agree with the above comment. The inserted table can have 1 to n rows.

I have two other suggestions other than a trigger.

You can create a function to wrap up the business logic in a neat package.

1 - Can you change the table design and add a persisted computed column ?

Use the above function in the design.

2 - How about creating a view with the calculated field in the SELECT statement?

Use the above function in the design.

Last but not least, a trigger solution that works for both null and zero values.

--
-- Sample table
--

-- Use temp database
USE TEMPDB;
GO

-- Remove old object
IF OBJECT_ID('DBO.INVESTOR') > 1
    DROP TABLE DBO.INVESTOR
GO

-- Create new object
CREATE TABLE DBO.INVESTOR
(
    INVESTOR_ID INT IDENTITY(1, 1),
    INVESTOR_PRIN_BAL_PURCHASED MONEY,
    INVESTOR_DISC_PREM_DOLLAR MONEY,
    INVESTOR_SRP_PREM_DOLLAR MONEY,
    INVESTOR_ADMIN_FEE MONEY,
    INVESTOR_WIRE_FEE MONEY,
    INVESTOR_FLOOD_FEE MONEY,
    INVESTOR_TAX_SERVICE_FEE MONEY,
    INVESTOR_OTHER_FEE MONEY,
    INVESTOR_DISC_PREM_PERCENT REAL,
    INVESTOR_SRP REAL,
    PURCHASE_WIRE_AMOUNT MONEY
);


--
-- Sample trigger
--

-- Remove old object
IF OBJECT_ID('DBO.CALCULATE_FEILDS') > 1
    DROP TRIGGER DBO.CALCULATE_FEILDS
GO

-- Create new object
CREATE TRIGGER DBO.CALCULATE_FEILDS ON DBO.INVESTOR
FOR INSERT, UPDATE AS
BEGIN

    UPDATE 
        DBO.INVESTOR
    SET 
        INVESTOR_DISC_PREM_PERCENT = 
            CASE WHEN INVESTOR_PRIN_BAL_PURCHASED <> 0 THEN
                Coalesce(INVESTOR_DISC_PREM_DOLLAR, 0) /
                Coalesce(INVESTOR_PRIN_BAL_PURCHASED, 0) * 100
            ELSE 0 END,

        INVESTOR_SRP = 
            CASE WHEN INVESTOR_PRIN_BAL_PURCHASED <> 0 THEN
                Coalesce(INVESTOR_SRP_PREM_DOLLAR, 0) /
                Coalesce(INVESTOR_PRIN_BAL_PURCHASED, 0) * 100
            ELSE 0 END,
        PURCHASE_WIRE_AMOUNT = 
            Coalesce(INVESTOR_PRIN_BAL_PURCHASED, 0) -
            Coalesce(INVESTOR_ADMIN_FEE, 0) -
            Coalesce(INVESTOR_WIRE_FEE, 0) - 
            Coalesce(INVESTOR_FLOOD_FEE, 0) -
            Coalesce(INVESTOR_TAX_SERVICE_FEE, 0) - 
            Coalesce(INVESTOR_OTHER_FEE, 0)
    WHERE 
        INVESTOR_ID IN (Select i.INVESTOR_ID From inserted i)

END
GO

--
-- Sample data (zeros & nulls)
--

INSERT INTO DBO.INVESTOR
(
    INVESTOR_PRIN_BAL_PURCHASED,
    INVESTOR_DISC_PREM_DOLLAR,
    INVESTOR_SRP_PREM_DOLLAR,
    INVESTOR_ADMIN_FEE,
    INVESTOR_WIRE_FEE,
    INVESTOR_FLOOD_FEE,
    INVESTOR_TAX_SERVICE_FEE,
    INVESTOR_OTHER_FEE
) 
VALUES 
(0, 0, 0, 0, 0, 0, 0, 0),
(NULL, NULL, NULL, NULL, NULL, NULL, NULL, NULL);

-- Show the data
SELECT * FROM TEMPDB.DBO.INVESTOR

Answer 3

Try it like this, it should fix both problems:

ALTER TRIGGER [dbo].[SelfCalFieldsTrigger] ON [dbo].[dynTable]
FOR INSERT, UPDATE AS
BEGIN

    UPDATE [dbo].dynTable
        SET INVESTOR_DISC_PREM_PERCENT = Coalesce(INVESTOR_DISC_PREM_DOLLAR, 0)/
                Coalesce(INVESTOR_PRIN_BAL_PURCHASED, 0)*100,
            INVESTOR_SRP = Coalesce(INVESTOR_SRP_PREM_DOLLAR, 0)/
                Coalesce(INVESTOR_PRIN_BAL_PURCHASED, 0)*100,
            PURCHASE_WIRE_AMOUNT = Coalesce(INVESTOR_PRIN_BAL_PURCHASED, 0)-
                Coalesce(INVESTOR_ADMIN_FEE, 0)-
                Coalesce(INVESTOR_WIRE_FEE, 0)- Coalesce(INVESTOR_FLOOD_FEE, 0)-
                Coalesce(INVESTOR_TAX_SERVICE_FEE, 0) - Coalesce(INVESTOR_OTHER_FEE, 0)
    WHERE Account_id IN(Select i.Account_id From inserted i)

END