给线程自己生成的期望：不支持的引用类型：GLOB

Question

I have a bunch of devices I have to logon to and run a few commands on them. As it takes time and there are a bunch of them I want to parallelise the task, do a few of them at the same time. I've done it with Net::Telnet however I have to use Expect.pm now.

In my main thread I fill up the @FW array with hashrefs called \\%host thusly:

my $EXPECT =  new Expect();
$EXPECT->spawn("ssh $username\@$ip");
$host{'expect'} = $EXPECT;

push(@FW, \%host);

Then I do a thread pool/queue i nicked from perlmonks which I've used for a few other things so I know that approach does work however I'm getting the error (check my comment in the code below)

sub getWorkItems {
    my $host = pop(@FW);
    return $host ? $host : undef;
}

our $THREADS = 3;
my $Qwork    = new Thread::Queue;
my $Qresults = new Thread::Queue;

my @pool = map {
    threads->create(\&worker, $Qwork, $Qresults)
} 1 .. $THREADS;

while (my $workItem = getWorkItems()) { # ERROR HERE: Unsupported ref type: GLOB
    $Qwork->enqueue($workItem);
}
$Qwork->enqueue((undef) x $THREADS);

sub worker {
    my $tid = threads->tid;
    my ($Qwork, $Qresults) = @_;
    while (my $host = $Qwork->dequeue()) {
        backup($host->{'expect'}, $host->{'hostname'}, $host->{'ip'}, $host->{'username'}, $host->{'password'});
    }
    $Qresults->enqueue(undef); ## Signal this thread is finished
}

for (1 .. $THREADS) {
    while (my $result = $Qresults->dequeue()) {
        print "T$_  $result", "\n";
    }
}

foreach (@pool) {
    $_->join();
}

I've read on CPAN that I have to give each thread its own spawned expect, but what am I doing wrong? I'm trying to pass the object via the same hash along with the other arguments heres how the backup sub begins:

sub backup {
    my ($EXPECT, $hostname, $ip, $username, $password) = @_;

    print "$EXPECT, $hostname, $ip, $username, $password\n";

    my $auth = $EXPECT->expect(3, -re => "authenticity of host"); 

(I don't see that print statement)

Again, this question is not about my use of Expect (that works), it's about how to use Expect in threads.

Answer 1

Thread::Queue uses threads::shared under the hood, and threads::shared does not support all Perl data types. Especially it looks like GLOBs are not supported.

use threads;
use threads::shared;

my $foo :shared;
for my $val (1, "foo", qr{regexp}, ["array"], {"ha"=>"sh"}, \*STDOUT, sub { }) {
    eval { $foo = shared_clone($val) };
    warn "Setting to $val failed: $@" if $@;
}

With a threaded perl 5.18.1 I get:

Setting to (?^:regexp) failed: Unsupported ref type: REGEXP at shared.pl line 8.
Setting to GLOB(0x80184e798) failed: Unsupported ref type: GLOB at shared.pl line 8.
Setting to CODE(0x801aa78e8) failed: Unsupported ref type: CODE at shared.pl line 8.

I don't think you can do anything about it, other than not using threads, but instead using event-based mechanisms ( Event.pm , AnyEvent , POE ...) or even think about using traditional pipe + fork .