Excel中的宏控制周期错误

Question

I have this macro

Private Sub Workbook_BeforeClose(Cancel As Boolean)
Dim x As Integer
Dim S1 As String
Dim S2 As String


S1 = "Football"
S2 = "Basket"
x = 1
    Do
        If IsEmpty(Cells(x, 5)) And ((Cells(x, 3) = S1) Or (Cells(x, 3) = S2)) Then
            MsgBox "Insert a value in the empty cell"
            Cancel = True
        End If
        x = x + 1

    Loop Until Cells(x, 1) = ""


End Sub

When i click the "x" button to close the sheet if the column 5 is empty and the 3 column contains Football or Basket the macro makes a control and appear a Message box to alert that you have insert a value. The check goes but i don't know the MsgBox appears 16 times and not 1. Why?

Answer 1

Putting my comments into an answer. Adding more things as well.

1. Declare your variables/objects. You will be less prone to errors. If you are working with rows in Excel, it is better to declare them as LONG
2. Fully qualify your objects. For example which cells and in which sheet? If you want to check the cells in sheet1 but sheet2 is active when you are closing the workbook then you will not get the desired results
3. You are getting multiple messages as the loop keeps on going till it finds all matches. Exit the loop after the first match
4. Make your Message in the MsgBox more meaningful. How will the user know which cell is empty :)

Is this what you are trying? ( UNTESTED )

Private Sub Workbook_BeforeClose(Cancel As Boolean)
    Dim S1 As String, S2 As String
    Dim lRow As Long, i As Long
    Dim ws As Worksheet

    Set ws = ThisWorkbook.Sheets("Sheet1")

    S1 = "Football": S2 = "Basket"

    With ws
        '~~> Find the last row which has data
        '~~> we will loop till there
        lRow = .Range("A" & .Rows.Count).End(xlUp).Row

        For i = 1 To lRow
            If Len(Trim(.Range("E" & i).Value)) = 0 Then
                Select Case .Range("C" & i).Value
                    Case S1, S2
                        '~~> Tell user which cell is empty
                        MsgBox "Insert a value in the cell " & _
                        .Range("E" & i).Address

                        Cancel = True

                        '~~> Exit the loop after the first match
                        Exit For
                End Select
            End If
        Next i
    End With
End Sub