如果所有文件都超过3天，则批量文件删除目录中的子文件夹

Question

I need to complete my batch script. I have a path C:\\Users\\Mahmo03S\\Shaban. In that path there a several subfolders, eg. Ansys. In the subfolder Ansys there are even more subfolders = its a foldertree. My batch script needs to delete the Ansys folder if every files in the folder and the subfolders is older than 3 days. If just one file in Ansyn is modified in the last 3 days then nothing should happen with Ansys. I tried to make a solid solution but: The batch file deletes a subsubfolder in Ansys directory because the files in the subsubfolder is not modified since 3 days.

I got 3 batch files doing the task.

Script.bat

@echo off
setlocal enableextensions
pushd C:\Users\Mahmo03S\Desktop\Shaban

set /p check="Select a date:" 
Rem When prompted with above line type the date 3 days ago.

forfiles /c "cmd /c (IF @isdir==TRUE call C:\Users\Mahmo03S\Desktop\Search.bat "@path" "%check%")"

popd

Search.bat

set del=TRUE
forfiles /p %1 /d -%2 /s /m * /c "cmd /c (IF @isdir ==TRUE call C:\Users\Mahmo03S\Desktop\DeleteFolders.bat "@path" "%check%" "%del%")"

DeleteFolders.bat

set del=FALSE
if %del%==FALSE (rmdir /S /Q %1)

The problem is: I got a subsubfolder (eg hello) in the folder Ansys. In the hello folder every file is older than 3 days. The script deletes the hello folder which it should not do. It should only delete Ansys if EVERY file in the folder is older than 3 days. If just one file is modified in Ansys folder for the past 3 days nothing in the Ansys folder should be deleted.

I made the batch file so it deletes the Ansys folder if every file is older than 3 days. But it should not delete a subsubfolder just because the files in it is older than 3 days.

How can I do that?

Answer 1

A working solution can be made much simpler ;)

You can detect if FORFILES printed any result, and take action if nothing was printed.

Use FOR /D to iterate the direct child folders. For each folder, run FORFILES looking for files that are at or later than the cutoff date. If you didn't have to worry about ignoring folders, then you could simply take action based on the FORFILES return code. But you don't want to get a false positive based on a new but empty folder. You can detect if FORFILES printed any filenames using FINDSTR, and delete the folder tree if none were printed. FORFILES still prints an empty line if it finds a new folder, so you must search for a character using . instead of searching for a line using "^" .

@echo off
setlocal disableDelayedExpansion
set "root=C:\Users\Mahmo03S\Shaban"
set /p "cutoff=Enter a cutoff date (mm/dd/yyyy): "
for /d %%F in ("%root%\*") do (
  2>nul forfiles /p "%%F" /d %cutoff% /s /c "cmd /c if @isdir==FALSE echo @file"
) | >nul 2>nul findstr . || rd /s /q "%%F"

There are multiple methods posted on StackOverflow and elsewhere showing how to do date arithmetic in batch. I'm partial to a hybrid JScript/batch utility called getTimestamp.bat . It is pure script that runs on any modern Windows machine from XP onward - no 3rd party executable required. It is chock full of options, allowing you to do nearly any date computation you could ever imagine.

Assuming getTimestamp.bat is in your current directory, or better yet, somewhere within your PATH, then the following line can be used to compute your cutoff date instead of prompting for the date:

call gettimestamp -OD -3 -F {mm}/{dd}/{yyyy} -R cutoff

Answer 2

This uses a VBS script to calculate the date 3 days ago, and then checks if any files are younger than that, using xcopy, and if no files are younger than 3 days then it should remove the "C:\\Users\\Mahmo03S\\Shaban\\Ansys" folder and subdirectories.

3 days is a date calculation and not exactly 72 hours.

It's not tested.

@echo off
call :date today -3
echo mm-dd-yyyy 3 days ago was: %day%

xcopy "C:\Users\Mahmo03S\Shaban\Ansys\*.*" "%temp%\" /l /s /d:%day% |find ":" >nul

if %errorlevel% EQU 1 rd /s /q "C:\Users\Mahmo03S\Shaban\Ansys"

goto :EOF
:date
set date1=%1
set qty=%2
set separator=%~3
if /i "%date1%" EQU "TODAY" (set date1=now) else (set date1="%date1%")
echo >"%temp%\%~n0.vbs" s=DateAdd("d",%qty%,%date1%)
echo>>"%temp%\%~n0.vbs" WScript.Echo year(s)^&_
echo>>"%temp%\%~n0.vbs"         right(100+month(s),2)^&_
echo>>"%temp%\%~n0.vbs"         right(100+day(s),2)
for /f %%a in ('cscript //nologo "%temp%\%~n0.vbs"') do set result=%%a
del "%temp%\%~n0.vbs"
endlocal& set "YY=%result:~0,4%"&set "MM=%result:~4,2%"&set "DD=%result:~6,2%"
set "day=%MM%-%DD%-%YY%"