使用sed替换多个字符

Question

I have a string:

xy-uv>ab-cd-ed-ef-gh<

I need to be convert it to:

xy-uv>ab cd ef gh<

Basically, I need to replace the - with a space in all characters between the > and the < .

How can I do this using sed ?

Answer 1

One way to do this is:

sed 'h; s/.*>\(.*\)<.*/\1/; s/-/ /g; G; s/\(.*\)\n\(.*>\)\(.*\)\(<.*\)/\2\1\4/'

In a multiline script it would be:

h 
s/.*>\(.*\)<.*/\1/
s/-/ /g 
G 
s/\(.*\)\n\(.*>\)\(.*\)\(<.*\)/\2\1\4/

It is a common pattern when you want to make a substitution only for a specific part of a line. It takes advantage of the hold space ( h , G commands). Basically you make a copy of the line (from the pattern space) to the hold space. Then isolate the part between '>' and '<', and substitute '-' with ' '. Then use the multiline get G command to append the hold space to the pattern space. In between there will be a new line character (the G command is a multiline command). In the last line we simply rearrange the two lines using groups and the replacement metacharacters \\N (where N is the group number).

Answer 2

You can try this sed script :

s/>([^>]+)</\n>\1<\n/g
:loop
s/(\n[>][^ ]+)-([a-z ]*[<]\n?)/\1 \2/g
t loop
s/\n//g

Test:

sat:~# sed -r -f b.sed 
xy-uv>ab-cd-ed-ef-gh< 
xy-uv>ab cd ed ef gh<

Answer 3

This is much easier with awk than sed as you can do substitutions on given fields:

$ awk '{gsub(/-/," ",$2)}1' FS='>' OFS='>' file
xy-uv>ab cd ed ef gh<

Answer 4

这可能对您有用（GNU sed）：

sed -r ':a;s/(>[^<]*)-([^<]*<)/\1 \2/;ta' file