将查询的值赋予变量

Question

Help, I am using SQL Server as my database, and my back-end is VB.NET.

I want to assign the value of this query:

SELECT sum(productPrice) from cartTbl

to a variable, and then give the value to a textbox called totalPrice .

How do I perform this? Thank you in advance!

Answer 1

You should use ExecuteScalar() if using ADO.NET

Public Function GetProductPrice() As Integer 
    Dim ProdPrice As Int32 = 0
    Dim sql As String = "SELECT sum(productPrice) from cartTbl" 

    Using conn As New SqlConnection(connString)
        Dim cmd As New SqlCommand(sql, conn)
        Try
            conn.Open()
            ProdPrice = Convert.ToInt32(cmd.ExecuteScalar())
        Catch ex As Exception
            Console.WriteLine(ex.Message)
        End Try 
    End Using 

    Return ProdPrice 
End Function

You can then call this method to get the Price.

Dim prodPrice = GetProductPrice()

Answer 2

您可以使用

SELECT @var1=sum(productPrice) from cartTbl

Answer 3

Use an alias for your calculated column

 SELECT sum(productPrice) as prod_sum
 from cartTbl

Then you can read it like this

While dr.Read()     
     totalPrice.Text = dr("prod_sum")
End While

Answer 4

It is as simple as this, but please read some basic info on ADO.NET

Using con = new SqlConnection(.....constring here ....)
Using cmd = new SqlCommand("SELECT sum(productPrice) from cartTbl", con)
   con.Open()
   Dim result = cmd.ExecuteScalar()
   Console.WriteLine(result)
End Using
End Using

Answer 5

To expand on what has already been said, you could use the following to make it a little more flexable:

Private Sub Test()
    'Get/set connection string
    Me.TextBox1.Text = Me.SQLExecuteScalar(ConnectionString, "SELECT sum(productPrice) FROM cartTbl")
End Sub

Public Shared Function SQLExecuteScalar(ByVal ConnectionString As String, ByVal Query As String) As String
    Dim Result As String = Nothing

    Dim Exc As Exception = Nothing

    Using Conn As New SqlClient.SqlConnection(ConnectionString)
        Try
            'Open the connection
            Conn.Open()

            'Create the SQLCommand
            Using Cmd As New SqlClient.SqlCommand(Query, Conn)
                'Create an Object to receive the result
                Dim Obj As Object = Cmd.ExecuteScalar

                If (Obj IsNot Nothing) AndAlso (Obj IsNot DBNull.Value) Then
                    'If Obj is not NULL
                    Result = Obj.ToString
                End If
            End Using

        Catch ex As Exception
            'Save error so we can (if needed) close the connection
            Exc = ex

        Finally
            'Check if connection is closed
            If Not Conn.State = ConnectionState.Closed Then
                Conn.Close()
            End If

        End Try

    End Using

    'Check if any errors where found
    If Exc IsNot Nothing Then
        Throw Exc
    End If

    Return Result
End Function