如何在PEG.js中创建可选单词

Question

I'm trying to build a simple parser with PEG.js. I want the user to be able to input a series of keywords, with an optional "AND" between them, but I can't seem to get the optional and working. It always expects it, even though I've marked it with a ? (zero or one).

Paste this grammar into http://pegjs.majda.cz/online :

parse = pair+

pair = p:word and? { return p }

word = w:char+ { return w.join(""); }

char = c:[^ \r\n\t] { return c; }

and = ws* 'and'i ws*

ws = [ \t]

My goal is to have either of these inputs parse into an array of ["foo", "bar"]:

foo bar
foo and bar

Answer 1

Ok, nevermind. I figured it out. It was because I made the optional whitespace preceding the 'and' as part of the and rule, so it expected the rest of the rule. I just needed to move it out, into the pair rule, like so:

parse = pair+
pair  = p:word ws* and? { return p }
word  = w:char+ { return w.join(""); }
char  = c:[^ \r\n\t] { return c; }
and   = 'and'i ws*
ws    = [ \t]

Answer 2

Here is my answer:

start
  = words

words
  = head:word tail:(and (word))* {
    var words = [head];
    tail.forEach(function (word) {
      word = word[1];
      words.push(word);
    })
    return words;
  }

and
  = ' and '
  / $' '+

word
  = $chars

chars 'chars'
  = [a-zA-Z0-9]+

Answer 3

I know this is a very old question, but seeing how it wasn't answered and someone might stumble upon it I'd like to submit my answer:

Program
    = w1:$Word _ wds:(_ "and"? _ w:$Word { return w; })* _  {
        wds.unshift(w1);
        return wds;
    }
Word 
    = [a-zA-Z]+
 _
    = [ ,\t]*

The "and" is optional and you can add as many words as you want. The parser will skip the "and"'s and return a list of the words. I took the liberty of removing commas.

You can try it out https://pegjs.org/online with a string like:

carlos, peter, vincent, thomas, and shirly

Hope it helps someone.