使用批处理文件重命名文件夹路径中的文件名

Question

Below is the bat file:

@echo off
set "D=%date%"
echo "%D%"
ren "D:\empty\ EE_DG3-ERROR.txt" "D:\empty\ EE_DG3-ERROR_%D%.txt"
pause

I want to append the datetime to the filename.

example : D:\\empty\\ EE_DG3-ERROR.txt to D:\\empty\\ EE_DG3-ERROR_14oct2013.txt

can you please help me with your suggestions?

Answer 1

ren "D:\empty\EE_DG3-ERROR.txt" "EE_DG3-ERROR_%date:/=_%-%time::=_%.txt"

Answer 2

edited to give a month name

This isn't quite the format you asked for either: But the first four lines of this code will give you reliable YY DD MM YYYY HH Min Sec variables in XP Pro and higher.

@echo off
for /f "tokens=2 delims==" %%a in ('wmic OS Get localdatetime /value') do set "dt=%%a"
set "YY=%dt:~2,2%" & set "YYYY=%dt:~0,4%" & set "MM=%dt:~4,2%" & set "DD=%dt:~6,2%"
set "HH=%dt:~8,2%" & set "Min=%dt:~10,2%" & set "Sec=%dt:~12,2%"


if "%mm%"=="01" set "mmm=Jan"
if "%mm%"=="02" set "mmm=Feb"
if "%mm%"=="03" set "mmm=Mar"
if "%mm%"=="04" set "mmm=Apr"
if "%mm%"=="05" set "mmm=May"
if "%mm%"=="06" set "mmm=Jun"
if "%mm%"=="07" set "mmm=Jul"
if "%mm%"=="08" set "mmm=Aug"
if "%mm%"=="09" set "mmm=Sep"
if "%mm%"=="10" set "mmm=Oct"
if "%mm%"=="11" set "mmm=Nov"
if "%mm%"=="12" set "mmm=Dec"

set "fullstamp=%DD%%mmm%%YYYY%"

for %%a in ("D:\empty\EE_DG3-ERROR.txt") do ren "%%~a" "%%~na_%fullstamp%%%~xa"
for %%a in ("D:\empty\plot.log")         do ren "%%~a" "%%~na_%fullstamp%%%~xa"

Answer 3

try this,

set dirpath=D:\empty\
ren "%dirpath%EE_DG3-ERROR.txt" EE_DG3-ERROR_14102013.txt