在宏中取消引用时未定义的变量

Question

Here is my macro definition:

*(defmacro run-test (test)
   `(format t "Run test ~a ... ~a" ',test ,test))
*(run-test (= 1 1))
Run test (= 1 1) ... T
NIL

Everything works fine for now, so I've defined a second macro (to run multiple tests):

*(defmacro run-tests (&body body) 
   `(loop for tc in ',body 
      do (run-test tc)))
* (run-tests (= 2 (1+ 1)) (= 1 1))
Run test TC ... (= 2 (1+ 1) Run test TC ... (= 1 1)

This result is not I wanted, I wanted each value of tc to be replaced by the sexp and the value be evaluated in run-test. i tried to replace the line

          do (run-test tc)

with

          do (run-test ,tc)

but this signals an error

Undefined variable: TC

How can I change this to get the right result?

Answer 1

Look at the expansion of eg (run-tests (= 1 1)) :

(loop for tc in '((= 1 1)) do (run-test tc))

As you can see, the code tries to call (run-test tc) . But run-test operates on a form; it will not work when you pass a variable containing a form.

If you change your code to (run-test ,tc) you are trying to refer to the tc variable during macroexpansion time, but it's only bound at runtime.

One solution would be to do more at macroexpansion time:

(defmacro run-tests (&body body)
  `(progn ,@(loop for tc in body collect `(run-test ,tc))))

Answer 2

Just as an exercise. You could get rid of the macros:

(defun run-test (test)
  (format t "~%Run test ~a ... ~a" test (eval test)))

(defun run-tests (tests)
  (mapc 'run-test tests)
  (values))

* (run-tests '((= 2 (1+ 1))
               (= 1 1)))