以升序创建列表

Question

I want to create a list in ascending order:

program ejListas;

type 
    tLista = ^lista
  ; lista = record
       valor : Integer
     ; sgte : tLista
    end
  ;

procedure insertarOrdenado ( var lista: tLista; dato: Integer );
    var cursor
      , listaAux
          :tLista
      ;
    begin
        if ( lista <> nil ) then
            begin
                new ( listaAux );
                listaAux^.valor := dato;

                cursor := lista;
                while ( cursor^.sgte <> nil ) and ( cursor^.valor < dato ) do 
                    cursor := cursor^.sgte;

                listaAux^.sgte := cursor^.sgte;
                cursor^.sgte := listaAux;
            end
        else
            begin
                new ( lista );
                lista^.valor := dato;
                lista^.sgte := nil;
            end;
    end;

procedure imprimirLista ( lista: tLista );
    var cursor
          :tLista
      ;
    begin
        cursor := lista;
        while ( cursor <> nil ) do
            begin
                writeln ( cursor^.valor );
                cursor := cursor^.sgte;     
            end;    
    end;

var vLista :tLista;
    dato:Integer;

begin
    read ( dato );
    while ( dato <> -1 ) do
        begin
            insertarOrdenado ( vLista, dato );
            read ( dato );
        end;
    imprimirLista ( vLista );
end.

So, when I run the program, the inserted numbers are:

1 - 5 - 58 - 95 - 3 - 0

The expected result is:

0 - 1 - 3 - 5 - 58 - 95

But, when the programs writes the list:

1 - 0 - 5 - 3 - 58 - 95

So, what's the problem here?

Answer 1

Basically it's because your program can't insert a node before the list you build, because your "Cursor" variable, after which you insert elements, starts with the first element.

My suggested improvement of procedure "insertarOrdenado" is:

procedure insertarOrdenado ( var lista: Tlista; dato: Integer );
var cursor, listaAux:Tlista;
begin
    if ( lista <> nil ) then
    begin
        new ( listaAux );
        listaAux^.valor := dato;

        cursor := lista;
        while ( cursor^.sgte <> nil ) and ( cursor^.sgte^.valor < dato ) do
            cursor := cursor^.sgte;

        if (cursor^.valor > dato) then
        begin
            listaAux^.sgte := cursor;
            lista := listaAux;
        end
        else
        begin
            listaAux^.sgte := cursor^.sgte;
            cursor^.sgte := listaAux;
        end;
    end
    else
    begin
        new ( lista );
        lista^.valor := dato;
        lista^.sgte := nil;
    end;
end;