windows批处理文件到zip然后ftp文件

Question

I currently have to windows batch files the first takes all files in a directory ending .bak and adds them to a rar file with todays date in the name

the second one ftp the rar file to another server.

the first ones code is

set path="C:\Program Files\WinRAR\";%path%
set date=%dd-mm-yyyy%
rar a D:\backups\dbs.rar -ri1 -mt2 -ag[dd-mm-yyyy] -m5 D:\backups\*.BAK
del D:\backups\*.BAK

which is called from inside sql server manager when its finished backing up the databases but could easily be run from a scheduled task

the seconds code is

@echo off
echo user Dbusser> ftpuploader.dat
echo ftppassword>> ftpuploader.dat
echo bin>> ftpuploader.dat
echo put %1>> ftpuploader.dat
echo quit>> ftpuploader.dat
ftp -n -s:ftpuploader.dat 127.0.0.1
del ftpuploader.dat

which I manually called from a cmd promt with the name of the rar file as an argument

ftpuploader.bat d:\pathtorar\dbs[21-10-2013].rar

what I want to know is can anyone tell me how to either merge the two files so it automatically uploads the file once its created and finished it or automate the schedule task to that it changes the date bit in the name of the rar file every day

thanks

Answer 1

This requires XP Pro and higher to use Wmic.

It sets the variable with the date, in a reliable manner, and uses that to create the RAR filename and also launch the FTP batch file.

I changed this line if not errorlevel 1 del D:\\backups\\*.BAK which should protect the *.bak files from being deleted if the RAR archiving fails for any reason.

@echo off
for /f "tokens=2 delims==" %%a in ('wmic OS Get localdatetime /value') do set "dt=%%a"
set "YY=%dt:~2,2%" & set "YYYY=%dt:~0,4%" & set "MM=%dt:~4,2%" & set "DD=%dt:~6,2%"

set "datestamp=%DD%-%MM%-%YYYY%"

set path="C:\Program Files\WinRAR\";%path%
rar a D:\backups\dbs[%datestamp%].rar -ri1 -mt2 -m5 D:\backups\*.BAK
if not errorlevel 1 del D:\backups\*.BAK
ftpuploader.bat D:\backups\dbs[%datestamp%].rar

Answer 2

Few things that I don't like in your script: I have no idea what set date=%dd-mm-yyyy% is doing .Not sure when the *bak files are deleted.If you are trying to upload binary files you need to set also the ftp script in binary mode. Here's one possible way to do this without temp files:

!&cls&echo off&setlocal ENABLEDELAYEDEXPANSION
!goto :end_ftp
!rem :: ftp part
open server
Dbusser
ftppassword
prompt
binary
mput *.BAK
bye

:end_ftp
set path="C:\Program Files\WinRAR\";%path%

rem get _date in format DD-MM-YYYY 
Set /A "Jan=1,Feb=2,Mar=3,Apr=4,May=5,Jun=6,Jul=7,Aug=8,Sep=9,Oct=10,Nov=11,Dec=12"
Type Nul >"%TEMP%\~.ddf"
Makecab /D RptFileName="%TEMP%\~.rpt" /D InfFileName=Nul /F "%TEMP%\~.ddf" >Nul
Set /P "timestamp=" <"%TEMP%\~.rpt"
For /F "tokens=3-9 delims=: " %%a In ("%timestamp%") Do (
    Set /A "year=%%g,month=%%b,day=1%%c-100"
)
Del /Q "%TEMP%\~.*"
Echo year=%year% month=%month% day=%day%
set "_date=%day%-%month%-%year%"
rem date is ready to use

rar a D:\backups\dbs.rar -ri1 -mt2 -ag[%_date%] -m5 D:\backups\%_date%\*.BAK

pushd D:\backups\%_date%\*.BAK
ftp -s:%~dpsnx0
popd
del D:\backups\%_date%\*.BAK /Q /F 
RD /S /Q D:\backups\%_date%\

The idea is that you are creating a directory with date name (I suppose your date format is dd-mm-yyyy) , then starts the ftp in this directory and using prompt (to surpass the prompting) and then using mput to upload all files with .bak extension.So no parameters are needed for the ftp script.For here are more explanations for self-contained ftp scripts.