Spreadsheet :: WriteExcel编写公式时，将其视为字符串

Question

I am writing the VLOOKUP formula to an excel. i tried directly writing the formula using write_formula. I used to get #VALUE! error in excel when i hit ctrl+shift+enter in excel it works fine. Also tried with store_formula & repeat formula same error.

Looks like the formula is considered as string. Is there a way to overcome this problem? Please help!

my $i = 0;
foreach (@col){
my $op_mode_lookup = $worksheet1->store_formula("=VLOOKUP(B16,DB Sheet!A2:D5,".(${i}+1).",FALSE)");
.
.
.
$worksheet1->repeat_formula('B'.$row_count, $op_mode_lookup, undef);
$i++;
}

I tried replacing the "store_formula("=VLOOKUP(B16,DB Sheet!A2:D5,".(${i}+1).",FALSE)");" with below still the same error.

store_formula('=VLOOKUP(B16,DB Sheet!A2:D5,'.(${i}+1).',FALSE)'); store_formula('=VLOOKUP(B16,DB Sheet!A2:D5,2,FALSE)');

Is there an alternative perl module for Spreadsheet::WriteExcel, which would overcome this issue?

Answer 1

There are several issues here:

1. The sheet name DB Sheet contains a space so Excel requires that it is enclosed in single quotes when used in formulas, like this: "=VLOOKUP(B16,'DB Sheet'!A2:D5,1,FALSE)" .
2. You are using store_formula() repeatedly in a loop. This is inefficient and incorrect. The point of store_formula() is that the expensive formula parse is only done once and that the pre-parsed formula can then be reused via repeat_formula() . The is explained at some length in the documentation and shown in numerous examples . You should go back and the docs carefully and then try to apply the methodology correctly or avoid using it if it isn't something that you require.
3. There is a known (but not easily fixable) bug that can affect VLOOKUP formulas when used from Spreadsheet::WriteExcel. A workaround is shown in the code below.

So, fixing these issues would give something like this:

#!/usr/bin/perl -w

use strict;
use Spreadsheet::WriteExcel;

my $workbook  = Spreadsheet::WriteExcel->new( 'demo.xls' );
my $worksheet1 = $workbook->add_worksheet();
my $worksheet2 = $workbook->add_worksheet('DB Sheet');

$worksheet1->write( 'B16', 1 );

for my $row ( 0 .. 7 ) {
    $worksheet2->write( $row, 0, $row );
}

my $op_mode_lookup = $worksheet1->store_formula(
                     "=VLOOKUP(B16,'DB Sheet'!A2:D5,1,FALSE)");

# Workaround for VLOOKUP bug in WriteExcel.
@$op_mode_lookup = map {s/_ref2d/_ref2dV/;$_} @$op_mode_lookup;

my @col = (0, 1, 2, 3);
my $row_count = 1;

foreach ( @col ){
    $worksheet1->repeat_formula('B' . $row_count, $op_mode_lookup, undef);
    $row_count++;
}

__END__

However , I would advise avoiding all of this store_formula() code and workaround and just use Excel::Writer::XLSX instead.

It is API compatible with Spreadsheet::WriteExcel and has faster and non-buggy formula support.