haskell中元组列表中4的唯一组合

Question

I have a list of tuples that repeats and is in no particular order. heres an example

let list = [(0,0), (0,1), (1,0), (1,1), (1,2)]

I want to filter this list and get every unique combination of 4 tuples from the list

I found example code to get a unique list where order doesn't matter and i'm not sure how to adapt it to get a unique set of 4.

with the above list the output there would be 2 unique sets of 4.

     [(0, 0), (0, 1), (1, 0), (1, 1)] 
     [(0, 1), (1, 0), (1, 1), (1, 2)] 
     [(0, 0), (0, 1), (1, 0), (1, 2)]  
     [(0, 0), (0, 1), (1, 1), (1, 2)]  
     [(0, 0), (1, 0), (1, 1), (1, 2)]

Answer 1

Something like this in the list monad lets you pick out all combinations easily. The Set.fromList gives us (==) defined on Set.Set s which ignore order.

import           Data.List ((\\), nub)
import qualified Data.Set as Set

someFours xs = nub $ do
  let xs' = nub xs
  choice1 <- xs'
  choice2 <- xs' \\ [choice1]
  choice3 <- xs' \\ [choice1, choice2]
  choice4 <- xs' \\ [choice1, choice2, choice3]
  return $ Set.fromList [choice1, choice2, choice3, choice4]

Answer 2

One solution is to use

let sane = nub list in filter (\x -> length x == 4) $ filterM (const [True, False]) sane

The sane = nub list is needed to remove duplicates in the original list. The filterM ... part get's you all the sets in the powerset of sane and from here we only select those with length 4 .

The above is not efficient due to the fact that we generate all elements of the powerset first. Use J. Abrahamson's answer if performance is needed.

Answer 3

A somewhat efficient and compact solution might be this (assuming I've correctly understood your question):

import Data.List (nub)

kSubsets :: (Eq a) => Int -> [a] -> [[a]]
kSubsets k = go k . nub
  where
    go 0 _      = [[]]
    go n []     = []
    go n (x:xs) = map (x:) (go (n-1) xs) ++ go n xs