VBA宏和Excel高级筛选器结果计算不匹配的唯一元素

Question

My problem is that I have to write a macro what gives back the unique elements from a column. I now that I can use advanced filter, but I have to do with macro for an assignment. I can test the results of the macro with the filter, and sometimes the macro gives back good result, sometimes don't. I know that the selection, selection part requires that I stay on the first row of the column. The code is:

Sub ElemSzámolás()
    Dim lista() As String
    Dim k As Integer
    Dim oszlop As Range

    k = 1
    ReDim lista(0 to 1)

    Set oszlop = ActiveSheet.Range(Selection, Selection)

    Do While oszlop.Offset(k).Value <> ""
        If UBound(Filter(lista, oszlop.Offset(k).Value)) = -1 Then
            lista(Ubound(lista)) = oszlop.Offset(k).Value
            ReDim Preserve lista(0 to UBound(lista) + 1)
        End If
        k = k + 1
    Loop

    MsgBox UBound(lista) & " db műsor van a listában", vbOKOnly, "Eredmény"    
End Sub

Thanks in advance!

Answer 1

My problem is that I have to write a macro what gives back the unique elements from a column.

Is this what you are trying? This will work on multiple columns as well.

Sub ElemSzámolás()
    Dim oszlop As Range, aCell As Range
    Dim col As New Collection, itm

    '~~> Check if what the user selected is a valid range
    If TypeName(Selection) <> "Range" Then
        MsgBox "Select a range first."
        Exit Sub
    End If

    Set oszlop = Selection

    '~~> Create a unique collection
    For Each aCell In oszlop
        If Not aCell = "" Then
            On Error Resume Next
            col.Add aCell.Value, CStr(aCell.Value)
            On Error GoTo 0
        End If
    Next

    '~~> This will give you the unique count
    MsgBox col.count & " unique items found"

    '~~> This will give you each of those unique items
    For Each itm In col
        Debug.Print itm
    Next
End Sub