PL / SQL中忽略的SQL语句

Question

So i'm writing a function for oracle db but I get errors saying that the sql statements were ignored and so expressions are missing.

The function:

CREATE OR REPLACE FUNCTION getQueueNumber
(student IN VARCHAR,course IN CHAR) 
RETURN INT
IS
   queuePosition INT;
   date TIMESTAMP;
   BEGIN
       SELECT waitingDate INTO date
       FROM WaitingCourseStudent wcs 
       WHERE wcs.student=student AND wcs.course=course;
       IF SQL%NOTFOUND THEN queuePosition := NULL;
       ELSE
           SELECT COUNT(*) as pos
           INTO queuePosition
           FROM WaitingCourseStudent 
           WHERE waitingDate<=date;
      END IF;
      RETURN queuePosition;
END;

Full error message:

LINE/COL    ERROR
8/5     PL/SQL: SQL Statement ignored
8/29    PL/SQL: ORA-00936: missing expression
13/9    PL/SQL: SQL Statement ignored
16/20   PL/SQL: ORA-00936: missing expression 

Answer 1

What you're probably looking for, is error handling instead of just an if.

CREATE OR REPLACE FUNCTION getQueueNumber
  (p_student IN VARCHAR, p_course IN CHAR) 
RETURN INT
IS
  queuePosition INT;
  v_date TIMESTAMP;
BEGIN
   BEGIN
      SELECT waitingDate INTO v_date
      FROM WaitingCourseStudent wcs 
      WHERE wcs.student = p_student AND wcs.course = p_course;
   EXCEPTION
      WHEN NO_DATA_FOUND THEN RETURN NULL;
   END;

   SELECT COUNT(*) as pos
   INTO queuePosition
   FROM WaitingCourseStudent 
   WHERE waitingDate <= v_date;
   RETURN queuePosition;
END;

The inner BEGIN/END is for the exception handling. An exception can only be handled within a BEGIN/END block and since you needed to do something after your exception, you need an inner BEGIN/END. An alternative would be

CREATE OR REPLACE FUNCTION getQueueNumber
  (p_student IN VARCHAR, p_course IN CHAR) 
RETURN INT
IS
  queuePosition INT;
  v_date TIMESTAMP;
BEGIN
   SELECT waitingDate INTO v_date
   FROM WaitingCourseStudent wcs 
   WHERE wcs.student = p_student AND wcs.course = p_course;

   SELECT COUNT(*) as pos
   INTO queuePosition
   FROM WaitingCourseStudent 
   WHERE waitingDate <= v_date;
   RETURN queuePosition;

EXCEPTION
   WHEN NO_DATA_FOUND THEN RETURN NULL;
END;

Answer 2

SELECT waitingDate INTO date <--- (date is reserved keyword for denoting oracle datatype of date)
FROM WaitingCourseStudent wcs 
   WHERE wcs.student=student AND wcs.course=course;
   IF SQL%NOTFOUND THEN queuePosition := NULL;

Alternate suggestion :

Prefix your variables with v_ or something like that to avoid these kind of errors.

Answer 3

The correct answer is as follows:

CREATE OR REPLACE FUNCTION getQueueNumber (vstudent IN VARCHAR,vcourse IN CHAR) RETURN INT IS queuePosition INT; date1 TIMESTAMP; BEGIN SELECT waitingDate INTO date1 FROM WaitingCourseStudent WHERE student=vstudent AND course=vcourse; IF SQL%NOTFOUND THEN queuePosition := NULL; ELSE SELECT COUNT(*) INTO queuePosition FROM WaitingCourseStudent WHERE waitingDate <= date1; END IF; RETURN queuePosition; exception when no_data_found then return -1; when others then return -1; END;