如何使用动态密码保护Workbook_Open事件上的工作表

Question

I have this code:

Private Sub Workbook_Open()

Dim wSheet As Worksheet
Dim my_code As String
Dim x As Long, y As Integer
Dim Pass_word, Prev_pass As String

my_code = Val(Format(Date, "#")) * 397

Pass_word = create_pass(my_code)

For Each wSheet In Worksheets
    On Error GoTo errhandler
    wSheet.protect Password:=Pass_word, _
    UserInterFaceOnly:=True
Next wSheet

Exit Sub
errhandler:

x = 1
Do
my_code = Val(Format(Date - x, "#")) * 397
Prev_pass = create_pass(my_code)
For Each wSheet In Worksheets
    On Error GoTo move
    wSheet.Unprotect (Prev_pass)
Next wSheet
move:
If Err.Number <> 0 Then
    x = x + 1
    y = 0
    Err.Clear
Else
    For Each wSheet In Worksheets
        wSheet.protect Password:=Pass_word, _
        UserInterFaceOnly:=True
    Next wSheet
    y = 1
End If
Loop Until y = 1

Resume Next

End Sub

What I want to do is to protect sheets inside a workbook with a dynamic password that changes everyday based on the date.
What i'm having trouble with is how to change the set password every day.
I added the errhandler routine but it doesn't work.
create_pass is a function i created to generate the coded pass and i already tested it and it returns the right value.

Error occurs in this somewhere here:

For Each wSheet In Worksheets
    On Error GoTo move
    wSheet.Unprotect (Prev_pass)
Next wSheet

No line is highlighted so i cannot determine which is it exactly.
I added watch on Prev_pass and x and it gets the first values then throws up the error.
the returned error is:

Run-time error '1004":
Application-defined or object-defined error

Any help is much appreciated.

Answer 1

Like I mentioned in the comments, we can use a temp sheet which will store the password. And the reason is very simple. let's take this scenario. Let's say the workbook is protected with 16122013 as a password on 16/12 . Now this password will also be stored in a hidden temp sheet. We need to do this because, if you open the file on the 17th or any other day (could be after 1 year?) then it will read the old password and unprotect the sheet and then protect it again with the new password. For protecting a sheet, you will have to unprotect it first if the sheet is protected. And to know the old password, you will have to retrieve it from somewhere or Hack it.

Here is another method.

This will loop 365 times and try to unprotect your sheet based on your function create_pass . I have commented the code so you shouldn't face any problem in understanding it. But if you do then simple post back.

Sub Sample()
    Dim my_code As String, Ret As String
    Dim PrevDt As Date
    Dim n As Long

    my_code = Val(Format(Date, "#")) * 397

    '~~> Create the password
    Ret = create_pass(my_code)

    '~~> Loop till the password is not found
    Do
        '~~> Attempt to unprotect the sheet
        On Error Resume Next
        ActiveSheet.Unprotect Ret
        On Error GoTo 0

        '~~> Check if the sheet was unprotected
        If ActiveSheet.ProtectContents = False Then Exit Do

        '~~> If not then go back one date
        If PrevDt = #12:00:00 AM# Then PrevDt = Date - 1 Else PrevDt = PrevDt - 1

        my_code = Val(Format(PrevDt, "#")) * 397

        Ret = create_pass(my_code)

        '~~> This counter is required so that we can exit the loop after 365 days
        n = n + 1

        If n > 365 Then
            MsgBox "More than 365 passwords have been checked. Exiting now"
            Exit Do
        End If
    Loop
End Sub

Edit 1: (posting the actual Workbook_Open event)

Private Sub Workbook_Open()

Dim ws As Worksheet
Dim my_code As String, Ret As String, my_pass As String
Dim PrevDt As Date
Dim n As Long

my_code = Val(Format(Date, "#")) * 397

'~~> Create the password
Ret = create_pass(my_code)
my_pass = Ret

'~~> loop in all WS
For Each ws In Worksheets
    '~~> Loop till the password is not found
    Do
        '~~> Attempt to unprotect the sheet
        On Error Resume Next
        ws.Unprotect Ret
        On Error GoTo 0

        '~~> Check if the sheet was unprotected
        If ws.ProtectContents = False Then Exit Do

        '~~> If not then go back one date
        If PrevDt = #12:00:00 AM# Then PrevDt = Date - 1 Else PrevDt = PrevDt - 1

        my_code = Val(Format(PrevDt, "#")) * 397

        Ret = create_pass(my_code)

        '~~> This counter is required so that we can exit
        '~~> the loop after 365 days
        n = n + 1

        If n > 365 Then
            MsgBox "More than 365 passwords have been checked. Exiting now"
            Exit Do
        End If
    Loop
    '~~> protect with the current day password
    ws.protect my_pass, , , , True
Next ws

End Sub

This unprotects WS's on opening then protect it with the current password.