Umbraco XSLT宏问题

Question

I copied an XSLT video player macro from an Umbraco 4.7.2 site into another Umbraco 4.0 site we have.

The macros are identical but the copied macro isn't running in 4.0, it produces no HTML or errors with all macro parameters holding values.

Are there some syntax differences between these two versions or am I making a mistake? XSLT isn't my native tongue, I'm more of a Razor guy.

Could someone point me toward the issue?

XSLT code:

<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE xsl:Stylesheet [
<!ENTITY nbsp "&#x00A0;">
]>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:msxml="urn:schemas-microsoft-com:xslt" xmlns:umbraco.library="urn:umbraco.library" version="1.0" exclude-result-prefixes="msxml umbraco.library">
  <xsl:output method="xml" omit-xml-declaration="yes"/>
  <xsl:param name="currentPage"/>
  <!-- set up vars -->
  <xsl:variable name="vidToPlay" select="/macro/vidToPlay"/>
  <xsl:variable name="previewImage" select="/macro/previewImage"/>
  <!-- END set up vars -->
  <xsl:template match="/">
    <!-- start writing XSLT -->
    <xsl:if test="$vidToPlay != '' and $previewImage != '' ">
      <xsl:variable name="showMe" select="umbraco.library:GetMedia($vidToPlay/node/@id, 0)/data [@alias = 'umbracoFile']"/>
      <xsl:variable name="preview" select="umbraco.library:GetMedia($previewImage/node/@id, 0)/data [@alias = 'umbracoFile']"/>
      <video controls="" poster="{$preview}">
        <source src="{$showMe}" type="video/mp4"/>
        <object width="640" height="360" type="application/x-shockwave-flash" data="/media/12209/player.swf">
          <!-- Firefox uses the `data` attribute above, IE/Safari uses the param below -->
          <param name="movie" value="/media/12209/player.swf"/>
          <param name="flashvars" value="controlbar=over&amp;file={$showMe}"/>
        </object>
      </video>
    </xsl:if>
  </xsl:template>
</xsl:stylesheet>

Answer 1

The XSLT displayed is from a previous Umbraco version, before the XML schema change.

<xsl:variable name="showMe" select="umbraco.library:GetMedia($vidToPlay/node/@id, 0)/data [@alias = 'umbracoFile']"/>
<xsl:variable name="preview" select="umbraco.library:GetMedia($previewImage/node/@id, 0)/data [@alias = 'umbracoFile']"/>

These lines should be

<xsl:variable name="showMe" select="umbraco.library:GetMedia($vidToPlay/node/@id, 0)/umbracoFile"/>
<xsl:variable name="preview" select="umbraco.library:GetMedia($previewImage/node/@id, 0)/umbracoFile"/>

More info on GetMedia from the Umbraco wiki: http://our.umbraco.org/wiki/reference/umbracolibrary/getmedia