VB.net MySQL插入无法正常工作

Question

I am trying to run an insert statement in vb.net to add a record. the line provided by the application works when I run it on mysql console - and the mysql query is erroring at adaptr.Fill(utable), I am now thinking it is because there is not any data to fill to my datatable. This exact format is working elsewhere in my application with a Select and an update statement. Any ideas?

Dim con As New MySqlConnection()
    Dim adptr As New MySqlDataAdapter
    Public utable As New DataTable



            con.ConnectionString = "server=localhost;" _
& "user id=user;" _
& "password=password;" _
& "database=DMT;"
            adptr = New MySqlDataAdapter(String.Format("INSERT INTO users (uname, pword, fname, lname, Usertype) VALUES ({0}, md5('{1}'), {2}, {3}, {4});", MySqlHelper.EscapeString(TextBox4.Text), MySqlHelper.EscapeString(passw), MySqlHelper.EscapeString(TextBox1.Text), MySqlHelper.EscapeString(TextBox2.Text), ulevl), con)
            Try
                adptr.Fill(utable)
            Catch err As Exception
                Dim strError As String = "Exception: " & err.ToString()
                MsgBox(strError)
            End Try

Answer 1

I would look into using parameters when building your SQL statement. You can use the code below to insert a record into the database.

Dim cb As New MySqlConnectionStringBuilder
cb.Database = "DMT"
cb.Server = "localhost"
cb.UserID = "user"
cb.Password = "password"

Using cnn As New MySqlConnection(cb.ConnectionString)
  Using cmd As New MySqlCommand("INSERT INTO users (uname, pword, fname, lname, Usertype) VALUES (@uname, md5(@pword), @fname, @lname, @usertype)", cnn)
    cmd.Parameters.AddWithValue("@uname", TextBox4.Text)
    cmd.Parameters.AddWithValue("@pword", passw)
    cmd.Parameters.AddWithValue("@fname", TextBox1.Text)
    cmd.Parameters.AddWithValue("@lname", TextBox2.Text)
    cmd.Parameters.AddWithValue("@usertype", ulevl)

    Try
      cnn.Open()
      cmd.ExecuteNonQuery()
    Catch ex As Exception
      MessageBox.Show(ex.ToString)
    End Try
  End Using
End Using