tsql多插入带回滚的事务中

Question

I have a stored procedure when exec it, it will insert into 2 tables several records.

let's say insert into author table a record and insert into book table several records(author's books).

how to make all insert in a transaction with rollback?

i read some articles/blogs, @@trancount/@@error/XACT_STATE() makes me confused.

what's the best approach?

here's my proc:

CREATE PROCEDURE [dbo].[proc_addAuthors]
    @bookid1 int,   @bookid2 int,   @bookid3 int,   @bookid4 int,   @bookid5 int,
    @authInfo 
AS
    insert into author...(leave out params)
    --get authorId
    ...

    --insert books (leave out validation checks...)
    insert into author2book(authorId, bookId) values(@authorid, @bookid1)
    ...

RETURN 0

Answer 1

If you just want to make sure that the inserts either both finishes succesfully, or both rolls back if an error occurs, you need to add the following to your stored procedure:

CREATE PROCEDURE [dbo].[proc_addAuthors]
    @bookid1 int,   @bookid2 int,   @bookid3 int,   @bookid4 int,   @bookid5 int,
    @authInfo 
AS

SET XACT_ABORT ON;  -- Automatically rollback if an error occurs.
BEGIN TRANSACTION;  

    insert into author...(leave out params)
    --get authorId
    ...

    --insert books (leave out validation checks...)
    insert into author2book(authorId, bookId) values(@authorid, @bookid1)
    ...

COMMIT TRANSACTION;

RETURN 0

Answer 2

CREATE PROCEDURE addTitle(@title_id VARCHAR(6), @au_id VARCHAR(11),
                          @title VARCHAR(20), @title_type CHAR(12))
AS

BEGIN TRAN
    INSERT titles(title_id, title, type)
    VALUES (@title_id, @title, @title_type)

    IF (@@ERROR <> 0) GOTO ERR_HANDLER

    INSERT titleauthor(au_id, title_id)
    VALUES (@au_id, @title_id)

    IF (@@ERROR <> 0) GOTO ERR_HANDLER

COMMIT TRAN

RETURN 0

ERR_HANDLER:
PRINT 'Unexpected error occurred!'
ROLLBACK TRAN
RETURN 1

Answer 3

Here is the way to go with modern TRY CATCH block to test the error

CREATE PROCEDURE [dbo].[proc_addAuthors]
    @bookid1 int,   @bookid2 int,   @bookid3 int,   @bookid4 int,   @bookid5 int,
    @authInfo 
AS
    BEGIN TRY
        BEGIN TRANSACTION
        insert into author...(leave out params)
        --get authorId
        ...

        --insert books (leave out validation checks...)
        insert into author2book(authorId, bookId) values(@authorid, @bookid1)
        ...
        COMMIT TRANSACTION
    END TRY
    BEGIN CATCH
        SELECT ERROR_MESSAGE() as errorMessage -- for example
        ROLLBACK
        RETURN 1 -- for example
    END CATCH

    RETURN 0

Answer 4

Using Try..Catch block gives you access to error functions, which you can use to get detailed information a about the error.

CREATE PROCEDURE [dbo].[proc_addAuthors]
@bookid1 int,   @bookid2 int,   @bookid3 int,   @bookid4 int,   @bookid5 int,
@authInfo 
AS
BEGIN
 SET NOCOUNT ON;

  DECLARE @NewAuthorID INT;


  BEGIN TRY

    BEGIN TRANSACTION
        insert into author...(leave out params)
        --get authorId
        SET @NewAuthorID = SCOPE_IDENTITY();  --<-- Get new AuthorID generated by Identity column

        --insert books (leave out validation checks...)
        insert into author2book(authorId, bookId)      --<-- use that NewAuthorID param here            
                values(@NewAuthorID, @bookid1)
        ...
    COMMIT TRANSACTION
    RETURN 0
  END TRY

  BEGIN CATCH 
      IF (@@TRANCOUNT > 0)
          ROLLBACK TRANSACTION

      DECLARE @ErrorNum int  
      SELECT @ErrorNum =  ERROR_NUMBER()
      SELECT ERROR_MESSAGE() AS ErrorMessage,
             ERROR_LINE()    AS ErrorLine, 
             --<--.... ( Other Error Functions )

      RETURN @ErrorNum
  END CATCH 
END