Excel VBA用户表单

Question

I've tried to work on it myself and re-edited the question. So I've done UserForm in Excel VBA (I've uploaded a picture of what it looks like

and I've used the following codes to transfer information from the textbox to excel rows

'Determine Empty Row
emptyRow= WorksheetFunction.Counta(Range("A:A"))+1
'Transfer into to cells
Cells(emptyRow, 1).Value= NOD_Text.Value
Cells(emptyRow,2).Value=TOD_Text.Value
Cells(emptyRow,3).Value=Program_Text.value
Cells(emptyRow,4).Value=email_Text.value
Cells(emptyRow,5).Value=OPN_Text.value
Cells(emptyRow,6).Value=CPN_Text.Value

I have multiple sheets same as the Stakeholder (Sheet A, Sheet B, Sheet C, Sheet D etc) and I want to transfer the above information depending on which checkbox is checked. Example, if checkbox A,B,C is clicked then above information is transferred to sheets A,B,C.

I'm not sure how to activate sheets depending on checkboxes of Stakeholders...

If A_Checkbox.Value=True then Worksheets(A).Activate then Cells(emptyRow, 1).Value= NOD_Text.Value
Cells(emptyRow,2).Value=TOD_Text.Value
Cells(emptyRow,3).Value=Program_Text.value
Cells(emptyRow,4).Value=email_Text.value
Cells(emptyRow,5).Value=OPN_Text.value
Cells(emptyRow,6).Value=CPN_Text.Value

not sure if above code is correct but the problem is..what if the person checkboxes 3 stakeholder (A,B,C)...? I'm not sure how to code that...

also, I want to put all informatoin in the Master Tab no matter which boxes are chekced, but i don't know how to always keep master tab activated...

i hope this is more clearer than before

Answer 1

To do this I'd use the TAG property of the controls.

In the TAG property of each text box I'd write the cell reference of where to paste the value - for example $B$2.

In the TAG property of each check box I'd write the sheet name linked to that control - for example Sheet1.

Then behind the command button I'd write code something like this:

Private Sub CommandButton1_Click()
    Dim ctrl As Control
    Dim ctrl1 As Control

    'Cycle through each control looking for checkboxes.
    For Each ctrl In Me.Controls

        If TypeName(ctrl) = "CheckBox" Then

            'If the checkbox is ticked
            If ctrl.Value = True Then

                With ThisWorkbook.Worksheets(ctrl.Tag) 'Grab the sheet name from the check box.

                    'Cycle through each control looking for textboxes.
                    For Each ctrl1 In Me.Controls
                        If TypeName(ctrl1) = "TextBox" Then
                            .Range(ctrl1.Tag) = ctrl1.Value 'Grab the cell address from the text box.
                        End If
                    Next ctrl1
                End With
            End If
        End If
    Next ctrl
End Sub

Answer 2

you need activate the sheet in the if and after know the firt empty cell:

If A_Checkbox.Value=True then 
   Worksheets("A").Activate
ElseIf B_Checkbox.Value=True then 
   Worksheets("B").Activate
End If

emptyRow=Activesheet.range("A1000000").end(XlUp).Row+1
Cells(emptyRow,2).Value=TOD_Text.Value

Answer 3

This Should do the trick:

Private Sub AddButton_Click()

Dim CB As Control

For Each CB In UserForm1.Controls

    If TypeName(CB) = "CheckBox" Then

        If CB.Value = True Then

            ShtNm = CB.Caption

            With ActiveWorkbook.Sheets(ShtNm)

                'Determine Empty Row
                emptyRow = .Range("A1").SpecialCells(xlCellTypeLastCell).Row + 1
                'Transfer into to cells
                .Cells(emptyRow, 1).Value = NOD_Text.Value
                .Cells(emptyRow, 2).Value = TOD_Text.Value
                .Cells(emptyRow, 3).Value = Program_Text.Value
                .Cells(emptyRow, 4).Value = email_Text.Value
                .Cells(emptyRow, 5).Value = OPN_Text.Value
                .Cells(emptyRow, 6).Value = CPN_Text.Value

            End With

        End If

    End If

Next CB

With ActiveWorkbook.Sheets("Master")

    'Determine Empty Row
    emptyRow = .Range("A1").SpecialCells(xlCellTypeLastCell).Row + 1
    'Transfer into to cells
    .Cells(emptyRow, 1).Value = NOD_Text.Value
    .Cells(emptyRow, 2).Value = TOD_Text.Value
    .Cells(emptyRow, 3).Value = Program_Text.Value
    .Cells(emptyRow, 4).Value = email_Text.Value
    .Cells(emptyRow, 5).Value = OPN_Text.Value
    .Cells(emptyRow, 6).Value = CPN_Text.Value

End With

End Sub