隐藏vim中的文本段以用于外部命令

Question

I am trying to create some sort of an ncurses-like menu appearence in vim.
Each line should have two fields: title, command
I read the input from stdin, formatted like: title COMMAND: command

item 1 COMMAND: echo hey
item 2 COMMAND: ls /
item 3 COMMAND: some-other-command

I want to show only the titles, like so:

item 1
item 2
item 3

But then I want to be able to run the command of this line, like so:

:.w !exec $(sed -r 's/COMMAND: (.*)/\1/')

But I haven't been able to hide the "COMMAND: ..." part.
How can I accomplish this?
Is vim not suited for such adventures?

Thank you...

Answer 1

first thing you need to take care is, :exec doesn't support [range] , that is, you cannot :% exec !whatever

If I understood you right, you want to for each line in your example, pick part of the line, the text after COMMAND: , as external shell command, and execute it.

You can try this command:

exec '!'.substitute(getline('.'),'.*COMMAND: ','','g')

To apply it on all your lines, you can consider to use macro, it is pretty easy. Don't put sed in, it doesn't help much.

If you want to first execute the cmd, and then modify the line, remove COMMAND:.. part, you can chain a :s after the exec ... :

exec '!'.substitute(....)|s/COMMAND:.*//

Answer 2

Here is how to accomplish what you originally intended. There are many options but I personally use the Unite plugin.

Install Unite

Add the following in your vimrc too see possibilities:

let g:unite_source_menu_menus = {}


let g:unite_source_menu_menus.filters = {
\'description' : 'Text filters',
\'command_candidates' : [
\  ["Remove empty lines"           , 'v/./d'],
\  ["Remove empty lines  [v]"      , "'<,'>v/./d"],
\  ['Condense empty lines'         , '%s/\n\{3,}/\r\r/e'],
\  ['Remove trailing white space'  , '%s/\s\+$//' ],
\  ['',''],
\]}

let g:unite_source_menu_menus.git = {
\ 'description' : 'Git commands (Fugitive)',
\ 'command_candidates' : [
\  ['git status       (Fugitive)                               '  , 'Gstatus'],
\  ['git diff         (Fugitive)                               '  , 'Gdiff'],
\  ['git commit       (Fugitive)                               '  , 'Gcommit'],
\  ['git cd           (Fugitive)                               '  , 'Gcd'],
\  ['',''],
\  ['git view file    (gitv)                                   '  , 'Gitv!'],
\  ['git view all     (gitv)                                   '  , 'Gitv'],
\]}

let g:unite_source_menu_menus.myhelp = {
\'description' : 'Interesting help topics',
\'command_candidates' : [
\  ['Executing shell commands in a window', 'h shell-window'],
\  ['File Searching and **', 'h starstar'],
\  ['Local directory .vimrc', "h 'exrc'"]
\]}

noremap <silent> sm  :<C-u>Unite -no-start-insert -quick-match -buffer-name=menu menu<CR>

You can launch menu with sm . You can change menu options and you can execute, edit, bookmark and do other tasks with commands. There is an option to filter items and use fuzzy search engine. Unite is unbelievable awesome plugin with many other benefits.

Another option is to use Forms plugin.

As for custom solution, this is a fast idea:

Given the file awesome.menu

item 11 COMMAND: echo 'hey'
item 2 COMMAND: !ls /
item 3 COMMAND: version

you can use the following function.

fu! Menu()

    let g:menu_bg = synIDattr(hlID('Normal'), 'bg#')
    let g:menu_fg = synIDattr(hlID('Normal'), 'fg#')
    let g:menu_s = 1

    exe 'highlight MyMenu guifg=' g:menu_fg
    match MyMenu /COMMAND:.*/
    nn <buffer> <space> :let g:menu_s = !g:menu_s<cr>:exe 'highlight MyMenu guifg=' . '<c-r>=g:menu_s ? g:menu_fg : g:menu_bg<cr>'<cr>
    nn <buffer> <cr> :exe substitute(getline('.'),'.*COMMAND: ','','g')<cr>

    norm <space>

    echo 'Menu Loaded'
endf


au BufCreate *.menu call Menu()

If you add above code in your vimrc and then load awesome.menu, your command text will be hidden and you can use "space" to toggle its visibility and "enter" to execute it.