perl将xsd转换为xml

Question

Working on this for hours now, and even with this tutorial, posted by saberworks in another similar question, I don't get it to work ...

So, I am trying to convert .xsd files into xml structures that can be accessed and completed afterwards through libXML or any other xml-parser .

If you take a look into the linked tutorial, is it possible to easily automate the second step, where saberworks creates the final data structure by hand?

How I understood, he just uses the output to get a "clue", some kind of guide, how the xml should look like. But is it possible to generate a whole perl structure that can be used (parsed) by libXML ?

And in case we already have the xml structure, how does XML::Compile/XML::LibXML handle with optional elements? If I don't put any values or elements in an optional element, does it appear in the final xml output? In case it does, is there any way to prevent this?

use warnings;  
use strict;
use Data::Dumper;
use XML::Compile::Schema;  
use XML::LibXML;

my $xsd = 'schema.xsd';
my $schema = XML::Compile::Schema->new($xsd);
my $xml_temp = $schema -> template('PERL', 'addresses');

# ***convert $xml_temp to "real" perl hash structure***

my $doc    = XML::LibXML::Document->new('1.0', 'UTF-8'); 
my $write  = $schema -> compile(WRITER => 'addresses'); 
my $xml    = $write -> ($doc, $xml_temp);
$doc -> setDocumentElement($xml);
print $doc -> toString(1);

Answer 1

Usually you want to generated dynamically the data that will be passed to the XML writer. For helping you with generating the correct data structure the template() method gives you a string representation of such a data structure along with some useful comments. If you want to see a minimal sample you can turn the string into an actual Perl datastructure with eval.

For simplicity I have included the sample schema from the tutorial in the adapted sample script.

Regarding your second question I would assume that optional elements are not put into the XML when you don't have them in your input.

use strict;
use warnings;

use Data::Dumper;
use XML::Compile::Schema;  
use XML::LibXML;

my $schema = XML::Compile::Schema->new(q{<xs:schema xmlns:xs='http://www.w3.org/2001/XMLSchema'>
  <xs:element name="addresses">
    <xs:complexType>
      <xs:sequence>
        <xs:element ref="address" minOccurs='1' maxOccurs='unbounded'/>
      </xs:sequence>
    </xs:complexType>
  </xs:element>

  <xs:element name="address">
    <xs:complexType>
      <xs:sequence>
         <xs:element ref="name" minOccurs='0' maxOccurs='1'/>
         <xs:element ref="street" minOccurs='0' maxOccurs='1'/>
       </xs:sequence>
    </xs:complexType>
  </xs:element>

  <xs:element name="name" type='xs:string'/>
  <xs:element name="street" type='xs:string'/>
</xs:schema>
} );

# this returns a string representation of a sample Perl datastructure
my $template = $schema->template('PERL', 'addresses');
print "The template:\n $template\n\n";

# turn the string representation into an actual Perl data structure
my $sample;
eval "\$sample = $template;";
print "The template turned into a Perl data structure:\n";
print Dumper( $sample );
print "\n\n";

# create XML from the sample Perl data structure
my $doc    = XML::LibXML::Document->new('1.0', 'UTF-8'); 
my $write  = $schema->compile(WRITER => 'addresses'); 
my $xml    = $write->($doc, $sample);
$doc->setDocumentElement($xml);
print "The generated XML:\n";
print $doc->toString(1);
print "\n\n";