从Access VBA在Excel中的单元格导航问题

Question

I have a small project to get data from Access using SQL queries and write the data into an excel. In preparation for that, I tried to do the following. The resulting output is "Hello" in (6,5) and "Hello Again" in (6,6). The "World" gets lost. I am little unsure how to navigate correctly. Most of the other variables that you see below are declared global.

Sub enterDataInCell()

Dim Cell As Object

Set xlApp = CreateObject("Excel.Application")
xlApp.DisplayAlerts = False

Set wb = xlApp.Workbooks.Open("H:\Documents\Misc-Work\BU\test.xlsx")

Set ws = wb.Sheets(1)

irow = 6
icol = 5

Set Cell = xlApp.Workbooks(1).Activesheet.cells(irow, icol)

Cell.Value = "Hello"

Set Cell = xlApp.Workbooks(1).Activesheet.cells(irow, icol).offset(0, 1)

Cell.Value = "World"

Set Cell = xlApp.Workbooks(1).Activesheet.cells(irow, icol).offset(0, 1)

Cell.Value = "Hello Again"

wb.Save
wb.Close
xlApp.DisplayAlerts = True

Set wb = Nothing
Set xlApp = Nothing
Set Cell = Nothing

End Sub

Answer 1

Because the value of iCol hasn't changed (and will not change, no matter how many times you use the .Offset method, you need to change the argument sent to the .Offset method.

Try:

Set Cell = xlApp.Workbooks(1).Activesheet.cells(irow, icol)

Cell.Value = "Hello"

Set Cell = xlApp.Workbooks(1).Activesheet.cells(irow, icol).offset(0, 1)

Cell.Value = "World"

Set Cell = xlApp.Workbooks(1).Activesheet.cells(irow, icol).offset(0, 2)

Cell.Value = "Hello Again"

Or you can explicitly refer to the row/column position and avoid .Offset altogether:

Set Cell = xlApp.Workbooks(1).Activesheet.cells(irow, icol)

Cell.Value = "Hello"

Set Cell = xlApp.Workbooks(1).Activesheet.cells(irow, icol + 1)

Cell.Value = "World"

Set Cell = xlApp.Workbooks(1).Activesheet.cells(irow, icol + 2)

Cell.Value = "Hello Again"

Alternatively, you can define the Cell object, and then set it as a new cell using the Offset method.

Set Cell = xlApp.Workbooks(1).Activesheet.cells(irow, icol)

Cell.Value = "Hello"

Set Cell = Cell.offset(0, 1)

Cell.Value = "World"

Set Cell = Cell.offset(0, 1)

Cell.Value = "Hello Again"