损坏的VB6集合。 无效的预选赛

Question

I am attempting to use a collection to store only one unique copy of each string returned from a database query.

When I come across a new one. I see if I already have it. If I do not, I add it to my collection and to my combobox. else I keep parsing.

When I compile, I get this error (code in picture too):

What do I need to change about my collection?

Answer 1

I would suggest that you try this.

Sub FillEstimatesRoofLaborTypeCombo()
    Dim rstEstimateFactorTypes As Recordset
    Dim Sqlstring As String

    Sqlstring = "Select Distinct FactorType " + _
                "From EstimateFactors " + _
                "Where Component = 'Roof' And ComponentPart = 'Labor' And FactorType Is Not NULL"

    Set rstEstimateFactorTypes = cnnSel.OpenRecordset(Sqlstring, dbOpenSnapshot)

    With rtsEstimateFactorTypes
        Do While Not .EOF
            frmEstimates.cboRoofLaborType.AddItem .Fields!FactorType
            .MoveNext
        Loop
    End With
End Sub

You will notice that the code is a lot simpler to code. I added a distinct to the select clause of your query and added another where clause condition on FactorType Is Not NULL. This will cause the database to only return rows that you want so there is no need to write code to filter out unique values.

You should also notice that this code executes considerably faster. If you're only getting a dozen or so rows from your database (with your original code) you may not notice a difference, but with more rows, the difference in execution time will become more obvious.

Answer 2

You have defined mostRecentList as array of collections and use it driectly.

Either you write:

Dim mostRecentList as Collection

[...]

Do While cnt < mostRecentList.count()

or you write

Dim mostRecentList() as Collection

[...]

Do While cnt < mostRecentList(lindex).count()

Besides you need to instanciate your collection before use ...

Answer 3

I think you need to change the declaration of your collection. Because this way you declared array of collections and therfore you got the error. Besides of this I agree with G Mastros, you can change the sql statement and so let the db server do the work for you. HTH

Sub FillEstimatesRoofLaborTypeCombo()
    ' this declares not a collection but a dynamic array of collections
    Dim mostRecentList() As Collection

    Debug.Print TypeName(mostRecentList)
    Debug.Print IsArray(mostRecentList)

    ' before using dynamic array ReDim must be used to alocate space in array
    ReDim mostRecentList(10)

    ' now mostRecentList has 10 elements each element is a collection
    ' before using any of this collection an new instance must be created
    Set mostRecentList(LBound(mostRecentList)) = New Collection

    ' now the first array element contains initialised instance of a collection
    ' and it is possible to add items to that collection
    mostRecentList(LBound(mostRecentList)).Add Item:="item_1", Key:="key_1"
    Debug.Print mostRecentList(LBound(mostRecentList)).Count

    ' *************************************************************************
    ' what you wanted was probably to have one collection instance like this
    ' declare without parenthesis
    Dim mostRecentListCol As Collection
    Set mostRecentListCol = New Collection

    Debug.Print TypeName(mostRecentListCol)
    Debug.Print IsArray(mostRecentListCol)
    Debug.Print mostRecentListCol.Count

End Sub

Output:

Object()
True
 1 
Collection
False
 0