通过重复除一个元素之外的所有其他元素，在XSLT中构造xml

Question

I am new to XSLT and tried googling to find solution but couldn't. I need to construct an xml in XSLT by repeating all other elements except the repetitive element.

Input XML: Here element D is repetitive. It might occur more than once. Depending on the number of times it appears, my output XML should contain the entire input XML multiple times except that element D is distributed. It would be really helpful if the answer is generic for n number of repetitions of D.

    <ABCD>
       <A> 
        <B> 
         <C>
            <D>d1</D>
            <D>d2</D>
            <D>d3</D>
         </C> 
        </B> 
       </A>
     </ABCD>

Output XML:

      <ABCD>
       <A> 
        <B> 
         <C>
            <D>d1</D>         
         </C> 
        </B> 
       </A>

       <A> 
        <B> 
         <C>
            <D>d2</D>
         </C> 
        </B> 
       </A>

       <A> 
        <B> 
         <C>
            <D>d3</D>
         </C> 
        </B> 
       </A>
     </ABCD>

Answer 1

Here is an XSLT 2.0 stylesheet tested with Saxon 9.5 HE:

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  exclude-result-prefixes="xs">

<xsl:variable name="nodes" as="node()*" select="//D"/>


<xsl:output indent="yes"/>

<xsl:template match="/*">
  <xsl:copy>
    <xsl:apply-templates select="$nodes" mode="copy"/>
  </xsl:copy>
</xsl:template>

<xsl:template match="*" mode="copy">
  <xsl:variable name="ancestors" select="ancestor::*[position() ne last()]"/>
  <xsl:variable name="anchor" select="."/>
  <xsl:apply-templates select="$ancestors[1]">
    <xsl:with-param name="ancestors" select="$ancestors"/>
    <xsl:with-param name="anchor" select="$anchor"/>
  </xsl:apply-templates>
</xsl:template>

<xsl:template match="*">
  <xsl:param name="ancestors"/>
  <xsl:param name="anchor"/>
  <xsl:choose>
    <xsl:when test=". is $anchor">
      <xsl:copy-of select="."/>
    </xsl:when>
    <xsl:when test=". intersect $ancestors">
      <xsl:copy>
        <xsl:copy-of select="@*"/>
        <xsl:apply-templates select="($ancestors[2], $anchor)[1]">
          <xsl:with-param name="ancestors" select="$ancestors[position() gt 1]"/>
          <xsl:with-param name="anchor" select="$anchor"/>
        </xsl:apply-templates>
      </xsl:copy>
    </xsl:when>
  </xsl:choose>
</xsl:template>

</xsl:stylesheet>

It work for any number of D elements but you somehow need to decide which elements to operate on so I defined a variable in the code. But if needed you could also define a parameter to take the element name:

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  exclude-result-prefixes="xs">

<xsl:param name="name" select="'D'"/>

<xsl:variable name="nodes" as="node()*" select="//*[local-name() eq $name]"/>

<xsl:output indent="yes"/>

<xsl:template match="/*">
  <xsl:copy>
    <xsl:apply-templates select="$nodes" mode="copy"/>
  </xsl:copy>
</xsl:template>

<xsl:template match="*" mode="copy">
  <xsl:variable name="ancestors" select="ancestor::*[position() ne last()]"/>
  <xsl:variable name="anchor" select="."/>
  <xsl:apply-templates select="$ancestors[1]">
    <xsl:with-param name="ancestors" select="$ancestors"/>
    <xsl:with-param name="anchor" select="$anchor"/>
  </xsl:apply-templates>
</xsl:template>

<xsl:template match="*">
  <xsl:param name="ancestors"/>
  <xsl:param name="anchor"/>
  <xsl:choose>
    <xsl:when test=". is $anchor">
      <xsl:copy-of select="."/>
    </xsl:when>
    <xsl:when test=". intersect $ancestors">
      <xsl:copy>
        <xsl:copy-of select="@*"/>
        <xsl:apply-templates select="($ancestors[2], $anchor)[1]">
          <xsl:with-param name="ancestors" select="$ancestors[position() gt 1]"/>
          <xsl:with-param name="anchor" select="$anchor"/>
        </xsl:apply-templates>
      </xsl:copy>
    </xsl:when>
  </xsl:choose>
</xsl:template>

</xsl:stylesheet>

If you simply want to take the elements that occur several times you could use

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  exclude-result-prefixes="xs">

<xsl:key name="name" match="*" use="node-name(.)"/>

<xsl:variable name="nodes" as="node()*" select="//*[key('name', node-name(.))[2]]"/>

<xsl:output indent="yes"/>

<xsl:template match="/*">
  <xsl:copy>
    <xsl:apply-templates select="$nodes" mode="copy"/>
  </xsl:copy>
</xsl:template>

<xsl:template match="*" mode="copy">
  <xsl:variable name="ancestors" select="ancestor::*[position() ne last()]"/>
  <xsl:variable name="anchor" select="."/>
  <xsl:apply-templates select="$ancestors[1]">
    <xsl:with-param name="ancestors" select="$ancestors"/>
    <xsl:with-param name="anchor" select="$anchor"/>
  </xsl:apply-templates>
</xsl:template>

<xsl:template match="*">
  <xsl:param name="ancestors"/>
  <xsl:param name="anchor"/>
  <xsl:choose>
    <xsl:when test=". is $anchor">
      <xsl:copy-of select="."/>
    </xsl:when>
    <xsl:when test=". intersect $ancestors">
      <xsl:copy>
        <xsl:copy-of select="@*"/>
        <xsl:apply-templates select="($ancestors[2], $anchor)[1]">
          <xsl:with-param name="ancestors" select="$ancestors[position() gt 1]"/>
          <xsl:with-param name="anchor" select="$anchor"/>
        </xsl:apply-templates>
      </xsl:copy>
    </xsl:when>
  </xsl:choose>
</xsl:template>

</xsl:stylesheet>