如何将我的Perl脚本与MySQL查询同步

Question

I am new in coding in every sense of the word so kindly bear with me.

I have created a Perl script that communicates with my PHP application but am stuck on the final hurdle of synchronizing them with MySQL queries. I want the Perl script to read table Syncorderrelation in my database, and to auto respond only once, sending a text message by posting the 'Auto Response' on my 'Outgoing Table') to any new entries that meets the following criteria:

1. The entry to have an updatetype of 1, which means the new entry is a new individual who has subscribed to a product.

2. The Perl script to read the new entry of DEST_MSISDN which is a field on the same Syncorderrelation table (just a phone number) and to reply to the number with an automated response (just a welcome message). This is done by only posting the 'Auto Response' on the 'Outgoing Table', where my PHP application takes over and sends the response on its own.

So my question is this: how do I go about creating a query whereby the Perl script will auto reply only to new entries in the Syncorderrelation table from The current time onwards. As currently, there are hundreds of other entries of which I don't want to trigger a response to.

But only send a reply to the New DEST_MSISDN (phone number) and only reply to this phone number and only do so once, and thus not keep resending the same welcome message, to the same number again and again.

Note : The only way that the script can know it is a new entry, will be through the ID Field. This is a unique field that is auto-generated every time a new entry enters into the Syncorderrelation table (which will now have increased from its current number of '440' to '441').

The script I have created posts correctly all the requisite fields from Syncoderrelation table to Outgoing table, but am unable to read the new Dest_Msisdn (phone number) from Syncorderrelation table and post the phone number to the Outgoing table. Without it the PHP application will not know where to send the welcome message to.

use strict;

use LWP::UserAgent;
use HTTP::Request::Common qw(POST);
use XML::Simple;
use Digest::MD5 qw(md5_hex);
use Time::Piece;
use DBI;
use Time::HiRes qw(usleep nanosleep);

my $dest_msisdn             = '';
my $link_id                 = '';
my $ID                      = '';
my $subscription_auto_reply = '';
my $user                    = '';
my $send_time               = '';
my $now                     = '';
my $correlator              = '2345';
my $sender_name             = '30045';
my $source                  = '30045';
my $text_message            = 'Dear Customer Welcome to our service';
my $ua                      = new LWP::UserAgent(keep_alive => 1);

#get all the configs

#get sms to be  sent
#set the connection

my $dbh = DBI->connect('DBI:mysql:Database404', 'Kapo', 'XXXXXXXXX') || die "Could not connect to database: $DBI::errstr";
my $j = 0;

while ($j < 1) {
  print "AutoResponse....\n";

  my $sql = "SELECT * FROM syncorderrelation WHERE updatetype = '1'";
  my $results = $dbh->selectall_hashref($sql, 'id');

  foreach my $id (keys %$results) {
    print "AutoResponder!!!.....\n";

    #get all the required columns
    #get all the required columns
    my $textMessage  = $results->{$id}->{text_message};    #$results->{$id}->{dest_msisdn};
    my $correlator   = $results->{$id}->{id};
    my $senderName   = $results->{$id}->{sender_name};
    my $linkID       = $results->{$id}->{link_id};
    my $textID       = $results->{$id}->{id};
    my $client       = $results->{$id}->{client};
    my $productId    = $results->{$id}->{product_id};
    my $dest_msisdn  = $results->{$id}->{dest_msisdn};
    my $text_message = $results->{$id}->{text_message};
    my $autoReply    = $results->{$id}->{autoreply};

#####send service

    my $user = 5;

    my $send_time = time;
    my $now       = time;

    #catch error

    my $sql1 = "INSERT INTO outgoing_sms(dest_msisdn, text_message, sender_name, link_id, correlator, send_time, client,  user_id, timestamp) VALUES ('$dest_msisdn', 'Dear Customer Welcome to our service', '$sender_name', '$link_id', '1161', '$now', '1',  '$user', '$now')";
    $dbh->do($sql1);

    #print $sql1;
###send
    print $sql1;

    #remove from outgoing table
    my $sql2 = "UPDATE incoming_sms SET sent_flag = 1 WHERE id='$correlator'";
    $dbh->do($sql2);

    print $sql2;

  }

  usleep(1000000);
}

Answer 1

I have many observations on your code

• Always use warnings as well as use strict

• Don't declare all you variables at the top of the program. They should be declared as close as possible to their first point of use

• You have a use for many modules that are unnecessary, and many variables that are unused or delcared twice. It is only polite to tidy up your code before asking for help with it. It is also much easier for you to work with a tidy program, but that is your own business.

• On a similar note, don't write comments unless you have to implement code that is so complex that it is difficult to understand. And say how some code works, not what it does: commenting set the connection before a call to DBI->connect is ridiculous

• You should use DBI's prepare and execute instead of do in most cases. Parameters should be passed in using placeholders, not by interpolating them into the SQL string

• It is best to ask the database what time it thinks it is, rather than using the local system time. That way the timestamps on different tables in the database can be compared properly

• You should put related changes to multiple tables inside a transaction so that, in the case of an error, one change cannot be made without the other

As far as I can tell you are looking for all the entries in syncorderrelation that have an updatetype of 1 and a corresponding row in incoming_sms that has sent_flag not set to 1. For this you need a JOIN on the two tables.

The code should look something like this. (See - one module, far fewer variable declarations!) But clearly I have been unable to check it without access to test data.

use strict;
use warnings;

use DBI;

my $dbh = DBI->connect('DBI:mysql:Database404', 'Kapo', 'XXXXXXXXX')
    or die "Could not connect to database: $DBI::errstr";

my $get_new_ids = $dbh->prepare(<<__ENDSQL__);
SELECT syncorderrelation.* FROM syncorderrelation INNER JOIN incoming_sms
ON incoming_sms.id = syncorderrelation.id
WHERE syncorderrelation.updatetype = 1 AND incoming_sms.sent_flag != 1
__ENDSQL__

my $insert_outgoing = $dbh->prepare(<<__ENDSQL__);
INSERT INTO outgoing_sms (
    dest_msisdn,
    text_message,
    sender_name,
    link_id,
    correlator,
    send_time,
    client,
    user_id,
    timestamp)
VALUES (?, ?, ?, ?, ?, ?, ?, ?, ?)
__ENDSQL__

my $update_incoming = $dbh->prepare('UPDATE incoming_sms SET sent_flag = 1 WHERE id = ?');

while () {

  while (my $data = $get_new_ids->fetchrow_hashref) {

    my ($now) = $dbh->selectrow_array('SELECT CURRENT_TIMESTAMP');

    $dbh->do('START TRANSACTION');

    $insert_outgoing->execute(
      $data->{dest_msisdn},                       # dest_msisdn,
      'Dear Customer Welcome to our service',     # text_message,
      $data->{sender_name},                       # sender_name,
      $data->{link_id},                           # link_id,
      1161,                                       # correlator,
      $now,                                       # send_time,
      1,                                          # client,
      5,                                          # user_id,
      $now,                                       # timestamp
    );

    $update_incoming->execute($data->{id});

    $dbh->do('COMMIT');
  }

  sleep 2;
}