XSLT-具有相同名称的多个父组

Question

Havent found an exact solution to this, for this basic example file I want to print the data of only the first 'Collection' (ie AH) and not the second, how do I go about that? Thanks

<?xml version="1.0" encoding="UTF-8"?>

<Library>
    <Collection>
        <CD>
            <Title>A</Title>
            <Artist>B</Artist>
        </CD>
        <CD>
            <Title>C</Title>
            <Artist>D</Artist>
        </CD>
        <CD>
            <Title>E</Title>
            <Artist>F</Artist>
        </CD>
        <CD>
            <Title>G</Title>
            <Artist>H</Artist>
        </CD>
    </Collection>
    <Collection>
        <CD>
            <Title>I</Title>
            <Artist>J</Artist>
        </CD>
        <CD>
            <Title>K</Title>
            <Artist>L</Artist>
        </CD>
    </Collection>
</Library>

Answer 1

This will place the contents of the first Collection inside an HTML table, and will ignore the contents of the other collections:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="1.0">

    <xsl:output indent="yes" />
    <xsl:strip-space elements="*"/>

    <xsl:template match="Library">
        <table>
            <tr><th>Title</th><th>Artist</th></tr>
            <xsl:apply-templates/>
        </table>

    </xsl:template>

    <!-- Ignoring all collections -->
    <xsl:template match="Collection" />

    <!-- Not ignoring the first collection -->
    <xsl:template match="Collection[1]">
        <xsl:apply-templates />
    </xsl:template>

    <xsl:template match="CD">
        <tr>
            <td><xsl:value-of select="Title" /></td>
            <td><xsl:value-of select="Artist" /></td>
        </tr>
    </xsl:template>

</xsl:stylesheet>

Answer 2

The following stylesheet:

<xsl:stylesheet version='1.0' xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output indent="yes"/>

    <xsl:template match="/Library">
        <table>
            <tbody>
                <tr>
                    <td>Title</td>
                    <td>Artist</td>
                </tr>
                <xsl:apply-templates select="Collection[position() = 1]"/>
            </tbody>
        </table>
    </xsl:template>

    <xsl:template match="Library/Collection">
        <xsl:for-each select="CD">
            <tr>
                <td><xsl:value-of select="Title"/></td>
                <td><xsl:value-of select="Artist"/></td>
            </tr>
        </xsl:for-each>

    </xsl:template>

</xsl:stylesheet>

when applied to your input XML, produces:

<?xml version="1.0" encoding="utf-8"?>
<table>
   <tbody>
      <tr>
         <td>Title</td>
         <td>Artist</td>
      </tr>
      <tr>
         <td>A</td>
         <td>B</td>
      </tr>
      <tr>
         <td>C</td>
         <td>D</td>
      </tr>
      <tr>
         <td>E</td>
         <td>F</td>
      </tr>
      <tr>
         <td>G</td>
         <td>H</td>
      </tr>
   </tbody>
</table>