VB代码不适用于.CSV导入Access 2007

Question

I am trying to import a .CSV file from a spacific folder in to access.

I have set up my own import specs by importing the first CSV file. I then writen this code

Sub ImportCSVFiles()
    Dim strPathFile As String, strFile As String, strPath As String
    Dim strTable As String
    Dim blnHasFieldNames As Boolean
    Const IMPORT_SPEC = "Megger Readings Import Specification"
' Change this next line to True if the first row in EXCEL worksheet
' has field names
    blnHasFieldNames = True

' Replace C:\Documents\ with the real path to the folder that
' contains the csv files
    strPath = "C:\Users\arbmaint\Desktop\Jumbo start loading test results"

' Replace tablename with the real name of the table into which
' the data are to be imported
    strTable = "Test Results"

    strFile = Dir(strPath & "*.csv")
    Do While Len(strFile) > 0
    strPathFile = strPath & strFile
    DoCmd.TransferText acImportDelim, "Megger Readings Import Specification", strTable, strPathFile, blnHasFieldNames


 Kill strPathFile

strFile = Dir()
Loop

End Sub

I then connected a button up to run this command and even though it complies okay nothing happens.

Any help would be great.

Answer 1

The line of code

strFile = Dir(strPath & "*.csv")

does the equivalent of the following at a command prompt:

dir "C:\Users\arbmaint\Desktop\Jumbo start loading test results*.csv"

and if strPath is the name of a folder then you won't get any matches to files inside the folder without a backslash \\ separator. Try this instead:

strFile = Dir(strPath & "\*.csv")