Delphi webbrowser - 如何从id中的标记名获取值

Question

i am using delphi 7 and making small program in which i use webbrowser to get value from tag inside id

here is html example of where value is saved

<div id="download" style="display: block;">

    <a style="display:none" href="blablabla"></a>
    <a href="Need This value"></a>
    <a style="display:none"blablabla"></a>
    <a style="display:none"blablabla"></a>
    <span style="margin-left:8px; color:#808080; overflow:hidden; white-space: nowrap"></span>
</div>

i can get innerHTML of id "download" my problem is after how to get value of "href" from tag "a"

Answer 1

If the <a> tag in question had a name or id assigned to it, you could have simply used the IHTMLDocument2.anchors collection to find it, for example:

var
  Doc: IHTMLDocument2;
  Anchor: IHTMLAnchorElement;
  Value: String;
begin
  Doc := WebBrowser1.Document as IHTMLDocument2;
  Anchor := Doc.anchors.item('name', 0) as IHTMLAnchorElement;
  Value := Anchor.href;
end;

But, since it does not have a name or id , you will have to dig through the DOM a little bit further, for example:

var
  Doc: IHTMLDocument3;
  Download: IHTMLElement;
  Coll: IHTMLElementCollection;
  Anchor: IHTMLAnchorElement;
  Value: String;
begin
  Doc := WebBrowser1.Document as IHTMLDocument3;
  Download := Doc.getElementById('download') as IHTMLElement;
  Coll := Download.children as IHTMLElementCollection;
  Coll := Coll.tags('a') as IHTMLElementCollection;
  Anchor := Coll.item(1, 0) as IHTMLAnchorElement;
  Value := Anchor.href;
end;

Answer 2

Don't know if it's the best solution, but it worked here:

function FindYourValue(block : string) : string;
var text, subtext : string;
    quant : integer;
begin
  text := block;
  if pos('<a href="',text) > 0 then
    subtext := copy(text,pos('<a href="',text) + 9,length(text));
  quant := pos('"',subtext);
  result := copy(subtext,1,9);
end;

Where BLOCK is the string you get from the <div id="download" style="display: block;"> routine.

Answer 3

The solution provided by Remy Lebeau @RemyLebeau should work. But you might meet exception, if the HTML does not contain the element you are expecting. If you want to write your code in a more secure way, I'd suggest you use Supports to query the Html element interfaces.

function ExtractUrlExample: TStringList; 
var
  Doc: IHTMLDocument3;
  Download: IHTMLElement;
  Coll: IHTMLElementCollection;
  I: Integer;
  Anchor: IHTMLAnchorElement;
begin
  Result := TStringList.Create;
  if Supports(WebBrowser1.Document, IHTMLDocument3, Doc) and
     Supports(Doc.getElementById('download'), IHTMLElement, Download) and
     Supports(Download.children, IHTMLElementCollection, Coll) and
     Supports(Coll.tags('a'), IHTMLElementCollection, Coll) then
  begin
    for I := 0 to Coll.Length - 1 do
      if Supports(Coll.item(I, 0), IHTMLAnchorElement, Anchor) then
        Result.Add(Anchor.href); // The Url you want to extract
  end;
end;