Neo4j Cypher：如何从路径中解压缩节点以允许进一步匹配？

Question

This question is a follow on to the question here

I have a graph that has a circular linked list. ( see here for an example ) Each node in the linked list points to a User. When querying the list I have to use a path statement as the list is circular and I do not want to retrieve nodes beginning from the u:USER node. In order to get the nodes of interest my query looks like this:

MATCH path=(nl:NODELINK { linkId:'cc' })-[:LINK*]->(u:USER)
RETURN nodes(path)

Once I have retrieved the path I would like to do further matching against the nodes in that path (the NODELINK's), somthing like the following:

MATCH path=(nl:NODELINK { linkId:'cc' })-[:LINK*]->(u:USER)
WITH nodes(path) AS nodeLinks
MATCH nodeLinks-[:PERSONLINK]->persons
RETURN persons

but if I try I get an error:

Error: Type mismatch: nodeLinks already defined with conflicting type Collection<Node> (expected Node) (line 3, column 7)
"MATCH nodeLinks-[:PERSONLINK]->persons"

How do I unpack the nodes of type NODELINK from the path in order to do further MATCH queries against them?

Answer 1

Try this one... kind of hacky but until there's an unwind operation, it will work.

MATCH path=(nl:NODELINK { linkId:'cc' })-[:LINK*]->(u:USER)
WITH [x in nodes(path) | id(x)] AS nodeLinkIds
MATCH (n1:NODELINK)
WHERE id(n1) in nodeLinkIds // this does efficient id lookups for the nodes in the list
MATCH n1-[:PERSONLINK]->persons
RETURN persons

Answer 2

There's now an UNWIND operator, so this should work:

MATCH path=(nl:NODELINK { linkId:'cc' })-[:LINK*]->(u:USER)
WITH nodes(path) AS x UNWIND x AS nodeLinks
MATCH nodeLinks-[:PERSONLINK]->persons
RETURN persons

I'd have thought we could do WITH UNWIND nodes(path) AS nodeLinks , but that gives me a cryptic Conversion = ''' error in Neo4j 2.2.0-M03.

Answer 3

Another option is to return the desired nodes as rows instead of a collection, and then do the further match with the rows of node. To return the nodes as rows, first specifies the nodes on the path and then compute the distance from a node:NODELINK to the node User, if the distance is longer than the distance from the starting node (eg'cc') to the end user node, then it should be excluded from the result.

MATCH path=(:NODELINK { linkId:'cc' })-[:LINK*]->(:USER)
WITH length(path) AS longest
MATCH p=(:NODELINK { linkId:'cc' })-[:LINK*]->(nodeLinks:NODELINK), p1 =(nodeLinks)-[:LINK*]->(:USER)
WITH nodeLinks, length(p1) AS n2u, longest
WHERE n2u <= longest
WITH nodeLinks
MATCH nodeLinks-[:PERSONLINK]->persons
RETURN persons

See the result from the console, http://neo4j-console-20.herokuapp.com/?id=87v0fy