如何用同一列中前一个单元格的数据填充CSV中的空白单元格？

Question

I have a large tab-seperated CSV file. It is missing some data, however:

1      cat    The cat ate the fish.
       dog    The dog played in the yard.
       fish   The fish went to the river.
2      eagle  The eagle flew in the sky.
              The eagle stopped in the mountains.
       bear   The bear ate the honey.

I need to fill all of the empty cells with whatever data appears in the previous rows. The output would look like this:

1      cat    The cat ate the fish.
1      dog    The dog played in the yard.
1      fish   The fish went to the river.
2      eagle  The eagle flew in the sky.
2      eagle  The eagle stopped in the mountains.
2      bear   The bear ate the honey.

• Preferably, the method only edits one specified column at a time, and must be run multiple times with different columns specified, to get the entire CSV fully filled.

Is there any way to fill the empty cells in a CSV with the contents of a previous cell in the same column that does have data?

Answer 1

awk solution to do the whole file:

awk -F\\t '
    {
      for (i=1;i<=NF;++i) if ($i != "") a[i] = $i;
      if (na < NF) na = NF;
      for (i=1;i<na;++i) printf "%s\t", a[i]
      printf "%s\n", a[na];
    }
    ' file.tsv

To just do a specified column:

awk -F\\t -v COL=2 '
    $COL=="" {$COL = saved}
    {saved = $COL; print}
    ' file.tsv

Answer 2

This should work for 1st and 2nd columns:

awk -F '\t' '$1 != ""{p1=$1} NF==3{p2=$2} p1 && $1 == ""{$1=p1} p2 && NF==2{$0=$1 OFS p2 OFS $2} 1' OFS='\t' file
1   cat     The cat ate the fish.
1   dog     The dog played in the yard.
1   fish    The fish went to the river.
2   eagle   The eagle flew in the sky.
2   eagle   The eagle stopped in the mountains.
2   bear    The bear ate the honey.

Answer 3

Works for any missing columns

awk -F\\t '
{ for (i=1;i<=NF;++i) 
    { if ($i != "") a[i] = $i;
      printf "%s\t", a[i]
    }
  printf RS
}' file