使用awk在文本文件中添加零

Question

I have some text files that look like this:

558903
5589157
55893434
55907235
.
.
.
7158709
71587172
7158748

I want to add zeros on lines that don't have the same number of characters as the other lines.

The output should look like this:

55890300
55891570
55893434
55907235
.
.
.
71587090
71587172
71587480

Thanks in advance.

Answer 1

这是使用awk的另一种方式：

awk 'FNR==NR { m = (m > NF ? m : NF); next } { print $0 * 10 ** (m - NF) }' FS= file{,}

Answer 2

Two pass Perl solution. It should work for huge files, too, that you can't keep in memory:

#!/usr/bin/perl
use warnings;
use strict;

my $length = 0;

open my $IN, '<', 'input.txt' or die $!;
while (<$IN>) {
    $length = length if length > $length;
}

$length--;       # Ignore newlines.
seek $IN, 0, 0;
while (<$IN>) {
    chomp;
    print $_, '0' x ($length - length), "\n";
}

Answer 3

Here is a way with awk :

$ awk '
{
    max = ((max > length($1)) ? max : length($1))
    a[NR] = $1
}
END { 
    for(x=1; x<=NR; x++) {
        n = max - length(a[x])
        while(n-->0) {
            a[x] = a[x] "0"
        }
        print a[x]
    }
}' file
55890300
55891570
55893434
55907235
71587090
71587172
71587480

Answer 4

awk solution without storing all numbers in memory:

awk 'NR==FNR {if (length($1)>m) m=length($1); next }
      length($1)<m { $1=$1*(10**(m-length($1))) } 1' file file

55890300
55891570
55893434
55907235
71587090
71587172
71587480

Answer 5

You can use BASH with bc to multiply the numbers appropriately.

while read l; do
    n=${#l}
    if [ $n -lt 8 ] && [[ $l =~ [0-9]+ ]]; then
        d=$((8-n))
        echo "$l*(10^$d)"|bc
    else
        echo $l
    fi
done < file

This will work if the highest amount of digits in the number is 8.