使用Interior.Color Excel 2010 VBA ActiveX控件进行While迭代时出现“ 1004”错误

Question

Thanks in advance for any advice.

I've got an Active X Check Box with the following code:

Private Sub CheckBox1_Click()

Dim h As Long, r As Long
h = 1400
r = 1429
If Sheets("SheetName").OLEObjects("CheckBox1").Object.value = True And Sheets("SheetName").CommandButton2.BackColor = RGB(192, 255, 192) Then
    While h <= r
        If Range("O1329") = "Width MM" Then
            If Cells(h, "N").value - Cells(h, "AA").value > Range("Y1317") Then
                Cells(h, "N").Formula = "=((INT(AA" & h & "))-1)+0.25"
                Cells(h, "AA").Interior.Color = RGB(250, 250, 200)
            End If
        Else
            If Cells(h, "N").value - Cells(h, "W").value > Range("Y1317") Then
                Cells(h, "N").Formula = "=((INT(W" & h & "))-1)+0.25"
                Cells(h, "W").Interior.Color = RGB(250, 250, 200)
            End If
        End If
    h = h + 1
    Wend
End If

End Sub

And it's hanging up in a few different places. (see EDIT notes at bottom)

Here's what I'm trying to do:

The range 1400-1429 spans several columns which contain relative data, in this case height measurements, so the while statement is for iterating through those cells. The data is line-specific, with values in columns AA and W coming from user input, and with a formula potentially adjusting those values in column N as a ' height standard '.

The first If statement is meant to check that both the checkbox is checked, AND that a neighboring toggle button is depressed (by checking the toggled color state. The button works very well, and changes color easily).

The If / Else statement is supposed to check to see if we're using Metric or inches, and should choose to pull values from the appropriate column ( W when we're using inches, and AA for metric). Cell O1329 populates with "MM" when we're using Metric. ( NOTE : all factoring on this project takes place in Inches. This particular Sub doesn't execute any of the MM-IN conversion)

The third set of If statements is meant to use the difference between individual cell values in certain columns in the range ( N , minus either W or AA ), and compare that difference to another cell ( Y1317 ). It proceeds only if the value in Y1317 is less than the difference of the values. The value in Y1317 represents an acceptable ' tolerance ' in the height measurements.

Once the code has decided which cell value to adjust, I want a formula to insert itself into the appropriate cell in the N column, and color the cell yellow that it refers to (in the AA or W user input columns as a flag, depending on unit of measurement).

The formula is meant to round the appropriate value down to the whole integer, subtract one (1), then add a quarter (0.25).

So, to recap, this code is meant to apply a standard to height measurements based on a certain tolerance: If the checkbox is checked, AND if the button is depressed, AND if the difference is greater than the allowed tolerance, determine which column to pull a value from (based on unit of measurement) and adjust that value (starting at row 1400) according to the formula, and flag the vertical-corresponding cell in the column where values are pulled from with a light yellow color. Do all of that 30 times in a row. (phew!)

Thanks again to the community for helping here, I'm glad to see that this is generating several responses that will build cumulatively to an answer. Feel free to notice that I'm new (to both SO, VBA, and coding in general) and don't hesitate to point me in 'better' directions. I'm trying to become a decent programmer.

EDIT:

1. I accidentally left the wrong cell reference on 'line 14'. Changed Cells(h, "AA").value to Cells(h, "W").value .
2. Thanks to Portland Runner for not assuming any previous experience. I don't know how I did w/out the f8 step 'till now.
3. My very first-ever f8 step-through showed me that validating the checkbox with True does indeed work, where xlOn did not. Researching the difference...
4. Stepping through further gives me a 1004 error (Application-Defined or Object-defined), on lines '11' and '16' (Interior.Color) which I take to mean that VBA doesn't like the way I'm referencing the range to color a particular cell (maybe?)
5. Right now I'm trying to fix the 1004 error, and researching Tim Williams' comment. The Object.Object is something I saw here , and as one of the posters on that forum noted, the more succint Sheets("SheetName").OLEObjects("CheckBox1").Object.value worked for them, so I'll try that. Qualifying with a sheet reference also seems like something fairly important to know how to do...

Answer 1

The left part of the main If will return always false, try to replace it by:

If Sheets("SheetName").CheckBox1 AND ...

Or keep it as it is and remove the = xlOn (this is the integer value 1, values for a CheckBox object are TRUE, FALSE)

If Sheets("SheetName").Shapes("CheckBox1").OLEFormat.Object.Object.value AND ....

Answer 2

Showing how to qualify Range and Cells with a sheet reference (otherwise they will default to the active sheet):

Private Sub CheckBox1_Click()

Dim h As Long, r As Long, rw as Long
Dim sht as WorkSheet
h = 1400
r = 1429

Set sht = Sheets("SheetName")

If sht.OLEObjects("CheckBox1").Object.value = True And _
   sht.CommandButton2.BackColor = RGB(192, 255, 192) Then

   'For.. loop is a better fit here...
   For rw = h to r 
        If sht.Range("O1329") = "Width MM" Then
            If sht.Cells(rw, "N").value - sht.Cells(rw, "AA").value > sht.Range("Y1317") Then
                sht.Cells(rw, "N").Formula = "=((INT(AA" & rw & "))-1)+0.25"
                sht.Cells(rw, "AA").Interior.Color = RGB(250, 250, 200)
            End If
        Else
            If sht.Cells(rw, "N").value - sht.Cells(rw, "W").value > sht.Range("Y1317") Then
                sht.Cells(rw, "N").Formula = "=((INT(W" & rw & "))-1)+0.25"
                sht.Cells(rw, "W").Interior.Color = RGB(250, 250, 200)
            End If
        End If
    Next rw
End If

End Sub