Perl中的BEGIN块

Question

Searching the Internet, I get that the BEGIN block will get evaluated and executed in the compile phase. But can the @INC or other variables be inherited?

Below is what I wrote for testing. The directory structure is as:

|-- alexpackages
|   |-- alex1.pm
|   `-- alex2.pm
|-- foo.pl
`-- main.pl

For each file:

cat alexpackages/alex1.pm

package alex1;

sub foo()
{
    print "this is alex1::foo\n";
}

1;

cat alexpackages/alex2.pm

package alex2;

sub foo2()
{
    print "this is is alex2::foo2\n";
}

1;

cat foo.pl

alex1::foo();

cat main.pl

BEGIN
{
    push(@INC, '~/programs/perl/alexpackages');
}

use strict;
use warnings;

use alex1;
use alex2;

#alex1::foo();           # 1. This works good
system("perl foo.pl");   # 2. This fails

Just as what my program tells that the @INC does not work for a new system call. It seems to me that system call will not inherit the system environment. Am I right?

And can how I make the environment variables to the following system call?

Answer 1

Processes started with system will inherit the environment variables from the calling process, but @INC is just a global Perl variable, not a system environment variable. It is not visible outside the Perl program.

A couple of notes on your code

• Package names, being globals, should be capitalised, so your packages should be Alex1 and Alex2 , in files alexpackages/Alex1.pm and alexpackages/Alex2.pm

• It is best to use the lib pragma to manipulate @INC , so

   use lib '~/programs/perl/alexpackages' 

  is best. And a use statement creates an implicit BEGIN block, so that is also unnecessary.

• It is wrong to use prototypes on Perl subroutines, so sub foo() should be just sub foo

• You may prefer to use Exporter to copy the symbols of a package into the calling code. That way you don't have to fully-qualify your subroutine name when you call it, like foo() instead of Alex1::foo()

The code would look like this

main.pl

use strict;
use warnings;

use lib '~/programs/perl/alexpackages';

use Alex1;

foo();

~/programs/perl/alexpackages/Alex1.pm

package Alex1;

use strict;
use warnings;

use base 'Exporter';

our @EXPORT = qw/ foo /;

sub foo {
  print "This is Alex1::foo\n";
}

1;

Answer 2

There are many ways to specify library search directories both from within a Perl script or the command line. Here are two things you could do to make another directory available to the Perl script you invoke with system :

$ENV{PERL5LIB} = "~/programs/perl/alexpackages";
system("perl foo.pl");


system("perl -I~/programs/perl/alexpackages foo.pl");

Both PERL5LIB and the -I switch are documented in perlrun .