Perl脚本在一个公共字段上联接两个文件

Question

i am writing a perl script to join fields from two different files into a 3rd new file based on a common field value in the 2 original files.

i have written the following script but it seems to go into an infinite loop. any suggestions on what i need to change?

#!/usr/bin/perl
#
open FILE, ">location.txt" or die$!;
open FILE1, "./checkins.txt" or die$!;
open FILE2, "./locations.txt" or die$!;

while (my $line1 = <FILE1> and my $line2 = <FILE2>) {
    chomp $line1;
    chomp $line2;
    @lines1 = split("\t", $line1);
    @lines2 = split("\t", $line2);

    while($lines2[0] = $lines1[5]) {
        print FILE
            "$lines2[0]"."\t"."$lines2[1]"."\t"."$lines2[2]"."\t"."$lines1[6]"."\t".
            "$lines1[7]"."\t"."$lines1[8]"."\n";
    }
}
close(FILE);
close(FILE1);
close(FILE2);

Answer 1

The 1990s called, and want their Perl syntax back...

Sorry about that. It's not your fault.

Perl syntax has changed quite a bit since its early days, and for some reason, most people still write in the older syntax form. It's taught in schools and people pick it up from examples in their workplace. Python developers decry the unreadable Perl syntax as proof that Perl is an old decrepit language which now belongs to the dustbin of history. But, in many ways, awful Perl syntax is proof how easy it is to pick up Perl and to learn it.

Always put use strict; and use warnings; at the top of your program. This will catch about 90% of the errors in Perl. It would have caught the error where you're using = instead of eq or == in your while statement. Get a new copy of Learning Perl (aka _The Llama Book). Go through it and pick up the new syntax. This will greatly improve your coding skills.

Another issue is that your inner while loop is an infinite loop. You're not really changing values of anything, so you're constantly looping over and over again. The below does the same thing:

while ( $foo ne $bar ) {
    print "Are we there yet?\n";
}

If $foo doesn't equal $bar , the above loop will go on printing Are we there yet? for billions of years until the sun uses up its last bit of helium fuel, and expands into a massive star that swallows up Earth's orbit (or until you get tired of it and hit Control-C).

If you don't want an infinite loop, you have to change at least one of the values you use in your while statement:

while ( $foo ne $bar ) {
    print "Are we there yet?\n";
    $foo = $bar;    # One more peep, and I'll stop the car!
}

Also, what happens if one file contains more lines than the other? I have a feeling what you want to do is read in one file into a hash, then loop through the other file. If that hash key exists in the second file, you then want to combine the lines. Unfortunately your question isn't exactly clear what you want to do.

Can you edit your question to better explain what you're attempting to accomplish. For example, if you can give us a sample input of your two input files and what you want your output file to look like. You only need to give us a few lines of each, but this will help us better understand what you want to do.

Answer 2

You're using an assignment = instead of a equality test eq , and it should be an if instead of a while .

while($lines2[0] = $lines1[5]) {

changing it to:

if ($lines2[0] eq $lines1[5]) {

Btw, ALWAYS include use strict; and use warnings; at the top of every script. And if you're doing file processing, use autodie; as well.

Here is a cleaned up version of your script with those pragmas and using lexical file handles:

#!/usr/bin/perl

use strict;
use warnings;
use autodie;

open my $outfh, ">", "location.txt";
open my $infh1, '<', "./checkins.txt";
open my $infh2, '<', "./locations.txt";

while (my $line1 = <$infh1> and my $line2 = <$infh2>) {
    chomp $line1;
    chomp $line2;
    my @lines1 = split("\t", $line1);
    my @lines2 = split("\t", $line2);

    if ($lines2[0] eq $lines1[5]) {
        print $outfh join("\t", @lines2[0,1,2], @lines1[6,7,8]), "\n";
    }
}
close($outfh);
close($infh1);
close($infh2);