如何启动使用 WMIC 最小化的 Windows 进程？

Question

Is there a way to start a process from a Windows 7 batch file (or from the command-line) using WMIC ? I am basically looking for the equivalent of START /MIN .

And not that I need it, but in case someone else might, what would be the START /MAX equivalent using WMIC ?

Answer 1

You'll need to write a vbs script. From http://msdn.microsoft.com/en-us/library/aa389388(v=vs.85).aspx and http://msdn.microsoft.com/en-us/library/aa394375(v=vs.85).aspx

Const SW_NORMAL = 1
strComputer = "."
strCommand = "Notepad.exe" 
Set objWMIService = GetObject("winmgmts:" _
    & "{impersonationLevel=impersonate}!\\" _
    & strComputer & "\root\cimv2")

' Configure the Notepad process to show a window
Set objStartup = objWMIService.Get("Win32_ProcessStartup")
Set objConfig = objStartup.SpawnInstance_
objConfig.ShowWindow = SW_NORMAL

' Create Notepad process
Set objProcess = objWMIService.Get("Win32_Process")
intReturn = objProcess.Create _
    (strCommand, Null, objConfig, intProcessID)
If intReturn <> 0 Then
    Wscript.Echo "Process could not be created." & _
        vbNewLine & "Command line: " & strCommand & _
        vbNewLine & "Return value: " & intReturn
Else
    Wscript.Echo "Process created." & _
        vbNewLine & "Command line: " & strCommand & _
        vbNewLine & "Process ID: " & intProcessID
End If

Answer 2

There is no need to search for a equivalent of start /min (unless there are additional requirements). Just use start /min

wmic process call create "cmd /c start /min notepad.exe"

Of course /max works the same.

Answer 3

Not using wmic , but I think it does what you need:

powershell.exe Start-Process -WindowStyle Minimized -PassThru notepad

Output contains PID:

Handles  NPM(K)    PM(K)      WS(K)     CPU(s)     Id  SI ProcessName
-------  ------    -----      -----     ------     --  -- -----------
     18       3     1232       1616       0,03  51784   1 notepad