使用正则表达式进行Perl排序

Question

I have a perl array of strings like this:

my @arr = ( "gene1 (100)", "gene2 (50)", "gene3 (120)", ... );

How can I sort the array by the integer in parentheses?

Answer 1

Using a transform to compare the first number in the string

use strict;
use warnings;

my @arr = ( "gene1 (100)", "gene2 (50)", "gene3 (120)");

my @sorted = map {$_->[0]}
             sort {$a->[1] <=> $b->[1]}
             map {[$_, /\b(\d+)\b/]} @arr;

print "$_\n" for @sorted;

Outputs:

gene2 (50)
gene1 (100)
gene3 (120)

Answer 2

The sort built-in in Perl lets you pass a code reference as its first argument to define how the sort should be done. Inside this code ref, you can use any function you want.

Since you want to do it with a regular expression, it makes sense to create a sub that matches the numbers in the parenthesis and use that in your sorting function.

You need to call it once for $a and $b , the two variables that will be compared to each other for each round of sorting pairs. You should use the <=> operator , which is used for sorting numbers in ascending order.

This is a very verbose version.

use strict;
use warnings;
use Data::Dump;

my @arr = ( "gene1 (100)", "gene2 (50)", "gene3 (120)",  );

dd sort { get_number($a) <=> get_number($b) } @arr;

sub get_number {
  my ( $string ) = @_;
  return $1 if $string =~ m/\((\d+)\)/;   
  return 0; # assume it goes last if there is no number
}

Output:

("gene2 (50)", "gene1 (100)", "gene3 (120)")

Answer 3

This shows the straightforward way. The sort block sets $aa and $bb to the values of the numbers in $a and $b respectively. Then <=> is used to compare them numerically.

There is no need for the much more obscure transformation method unless the basic technique proves to be too slow.

use strict;
use warnings;
use 5.010;

my @arr = ( "gene1 (100)", "gene2 (50)", "gene3 (120)",  );

my @sorted = sort {
  my ($aa) = $a =~ / \(  (\d+)  \) /x;
  my ($bb) = $b =~ / \(  (\d+)  \) /x;
  $aa <=> $bb;
} @arr;

say for @sorted;

output

gene2 (50)
gene1 (100)
gene3 (120)

Answer 4

The List::UtilsBy CPAN module provides a function, nsort_by which sorts a list of values by sorting into numerical order, the values returned by a block of code on each value.

In your case, it can be used to extract that number:

use List::UtilsBy 'nsort_by';

@sorted = nsort_by { m/\((\d+)/ and $1 } @strings

This is somewhat more efficient than a regular sort call with code to extract and compare the two numbers from $a and $b directly, as it only has to extract the number from each value once, rather than once for every pair-wise comparison.