从文本文件中删除字符串

Question

I'm trying to grab only the drive letter and drive path from the net use command. The problem is that I can get the drive letter and path but with my loop I also get a "Microsoft Windows Network" string.

I have started out using tokens=2,3 but that unfortunately cuts out any spaces in the drive path which I do not want.

So bassically what I am asking is, is there a way to delete a string from a variable or from the text file. I have tried using the findstr /v but that removes the whole line which is also undesirable.

:GetDrives
setlocal EnableDelayedExpansion
@echo off
cls
set i=0
for /F "tokens=2,*" %%a in ('net use ^| Find "\\"') do (
   set /A i+=1
   set array1[!i!]=%%a
   set array2[!i!]=%%b

)
set n=%i%
for /L %%i in (1,1,%n%) do echo !array1[%%i]! !array2[%%i]! >> DriveFile.txt

pause
GOTO:EOF

Below are examples of what I currently get and what I would like to be getting.

Net use befor script:

Status       Local     Remote                    Network

----------------------------------------------------------------------------
OK           H:        \\Server\User$\UID   Microsoft Windows Network
OK           X:        \\Server\Folder\Folder   Microsoft Windows Network
OK           Z:        \\Server\Folder\Folder Name
                                            Microsoft Windows Network
The command completed successfully.

This is the current out put of my code in the DriveFile.txt:

X:        \\Server\Folder\Folder   Microsoft Windows Network
Z:        \\Server\Folder\Folder Name

This is what happens when I use /F "tokens=2,3":

X:        \\Server\Folder\Folder
Z:        \\Server\Folder\Folder

This is what I would like to see:

X:        \\Server\Folder\Folder
Z:        \\Server\Folder\Folder Name

But also want it to extend out past more than just 4 tokens so if the file path mapped to Z drive where say "\\server\\Folder Name\\Folder Name\\Folder Name" I would still get the full file path.

Any help is greatly appreciated, thanks in advance.

Answer 1

for /f "tokens=2-3" %A in ('net use^|findstr  /i /c:"\\"')do echo %A %B

for /f "tokens=1-2* delims=:\" %A in ('net use^|findstr  /i /c:"\\"') do echo %A: \\%B %C %D %E

Answer 2

Unfortunately it is harder than it seems.

• The Status field can hold information or be empty.

• The Network field can have multiple values depending of network mapping. In my case i have "Microsoft Windows Network" and "Netware Services". So, there is no direct substitution.

• The Network field can be in the same line that the Remote field or can be on the next line, and as the Remote field may include spaces, checking the character at the column limit position is not reliable. It is necessary to delay the check until the next line is readed to determine if it contains remote data.

Sure, it can be done, but there are too much cases to handle. Some alternative options, and answer to asked question are:

@echo off

    setlocal enableextensions enabledelayedexpansion

    :: Option 1 - Enumerate and ask each drive

    for /f "delims=:" %%a in ('net use ^| find ":"') do (
        for /f "tokens=2" %%b in ("x%%a") do set "drive=%%b"
        for /f "tokens=2,* delims=\" %%b in ('net use !drive!:'
        ) do echo(!drive!: \\%%b\%%c
    )

    echo -----------------------------------------------

    :: Option 2 - Ask WMI

    for /f "tokens=2,3 delims=," %%a in (
        'wmic netuse get LocalName^, RemoteName^, Status /format:csv ^| find ":"'
    ) do echo(%%a %%b

    echo -----------------------------------------------

    :: Option 3 - Only one net use command

    set "drive="
    set "remote="
    for /f "skip=6 delims=" %%a in ('net use') do (
        for /f "tokens=1,2 delims=:" %%b in ("%%a") do (
            if "%%c"=="" (
                if defined drive (
                    echo(!drive! !remote!
                    set "drive="
                    set "remote="
                )
            ) else (
                if defined drive echo(!drive! !remote:~0,26!
                for /f "tokens=2" %%d in ("x%%b") do ( 
                    set "drive=%%d:" 
                    for /f "tokens=2,* delims=\" %%e in ("%%c") do set "remote=\\%%e\%%f"
                )
            )
        )
    )
    if defined drive echo(!drive! !remote:~0,26!

First option uses a first net use command to get the list of drives and for each of them (be careful, the status field can be empty, so a second for is used to retrieve the letter) the drive letter is retrieved and used to emit a new net use x: command to retrieve the path.

In the second option, wmic is used to retrieve the information from WMI.

The third option is the original problem. How to parse the net use command.

First option is slower (there is a initial net use and one net use x: for each drive) but second option, while faster, needs administrator rights. Third option is a nightmare but it is fast and does not require aditional rights.

edited there was a problem in option 1 handling tokens. Now corrected