Android Gradle构建无法添加第三方库

Question

buildscript {
    repositories {
        mavenCentral()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:0.11.+'
    }
}

apply plugin: 'android'

android {
    compileSdkVersion 19
    buildToolsVersion "19.1.0"

    defaultConfig {
        applicationId "uz.dev.app.todak"
        minSdkVersion 15
        targetSdkVersion 19
        versionCode 1
        versionName "1.0"
    }
    buildTypes {
        release {
            runProguard false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
        }
    }
}

dependencies {
    compile fileTree(dir: 'libs', include: ['*.jar'])
    compile 'com.android.support:support-v13:19.+'
}

I want to add this library in my project. https://github.com/astuetz/PagerSlidingTabStrip

dependencies {
    compile 'com.astuetz:pagerslidingtabstrip:1.0.1'
}

But Error!

Error:com.astuetz:pagerslidingtabstrip:1.0.1
<a href="searchInBuildFiles">Search in build.gradle files</a>

Occurrences of 'com.astuetz:pagerslidingtabstrip:1.0.1' in Project with mask 'build.gradle'

Answer 1

This library is available at mavenCentral. To resolve dependencies from mavenCentral you need to declare a repository. (The repository section in the buildscript block is just used to resolve buildscript dependencies):

buildscript {
    repositories {
        mavenCentral()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:0.11.+'
    }
}

apply plugin: 'android'

android {
    compileSdkVersion 19
    buildToolsVersion "19.1.0"

    defaultConfig {
        applicationId "uz.dev.app.todak"
        minSdkVersion 15
        targetSdkVersion 19
        versionCode 1
        versionName "1.0"
    }
    buildTypes {
        release {
            runProguard false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
        }
    }
}

repositories{
    mavenCentral()
}

dependencies {
        compile fileTree(dir: 'libs', include: ['*.jar'])
        compile 'com.astuetz:pagerslidingtabstrip:1.0.1'
        compile 'com.android.support:support-v13:19.+'
}