如何在vbscript中将类的属性设置为不同的类？

Question

I'm trying to do something like this in vbscript

Class cla
    Public a, b
End Class

Class clb
    Public c
End Class

Set mySubObj = new clb
mySubObj.c = "value_C"

Set myObj = new cla
myObj.a = "value_A"
myObj.b = mySubObj

msgBox(myObj.b.c)   

This doesn't work, basically I'm parsing an xml document, then processing a user defined map which can include vbscript, in the script the variable would be accessed like "myobj.bc" this is just a simple example but any help would be greatly appreciated.

Answer 1

I figured out how to do this, for more details you can look here http://www.activexperts.com/vbscript-powershell-component/vbscriptclasses/ below is the code that worked for me, hope this maybe useful to someone else.

Class ClassA 
    Private m_A 
    Private m_B 

    Public Property Get A
        A = m_A 
    End Property 

    Public Property Let A(value) 
        m_A = value 
    End Property 

    'Since this property is and object must use 
    'Set instead of Let, and must 
    'specifically Set the values 

    Public Property Get B 
        Set B = m_B 
    End Property

    Public Property Set B(value) 
        Set m_B = value
    End Property 
End Class 

Class ClassB
    Public C 
End Class 

Set a = New ClassA
a.a = "value1" 
Set a.b = new ClassB 
a.b.c = "value2" 

MsgBox(a.b.c) 'shows "value2