如何使用XSLT1.0在XML文件中替换ID元素及其所有参考元素

Question

I need to shorten some ID values and their references in an XML document using only XSLT...

Example XML doc:

<root>
 <firstChild>
  <ID>99999</ID>
 </firstChild>
 <secondChild>
  <IDRef>99999</IDRef>
 </secondChild>
 <thirdChild>
  <person>
   <IDRef>99999</IDRef>
  </person>
 </thirdChild>
</root>

Desired result after applying XSLT:

<root>
 <firstChild>
  <ID>1</ID>
 </firstChild>
 <secondChild>
  <IDRef>1</IDRef>
 </secondChild>
 <thirdChild>
  <person>
   <IDRef>1</IDRef>
  </person>
 </thirdChild>
</root>

Basically I need XSLT to find each ID tag, replace it with a value and then find any IDRef tags elsewhere in the document and replace those with the same as the ID tag.

Edit - The replacement value needs to be an incrementing number. I think that the best way to make it increment would be to do something with the position() function in xslt. For example:

<xsl:variable name="ReplacementID" Select="position()"/>

I am not too concerned with how to make the numbers increment at this stage, I am more concerned with how to (if it is possible): 1. match an ID tag, change its text node to a new value, 2. then match any IDRef nodes and replace their text with the same value as what was added to the ID tag in step 1 The value itself could be anything from a global variable to a param that is passed into the stylesheet.

Below is a very rough XSLT of what I am trying to do (it does not work)

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml"/>
<xsl:template match="/">
    <xsl:apply-templates select="@* | node()"/>
</xsl:template>

<xsl:template match="root/firstChild/ID">
    <xsl:variable name="currentID" select="."/>
    <xsl:variable name="replacementID">1</xsl:variable>
    <ID>
        <xsl:value-of select="$replacementID"/>
    </ID>
    <xsl:apply-templates select="IDRef[text() = $currentID]" mode="Replace">
        <xsl:with-param name="Replacement" select="$replacementID"/>
    </xsl:apply-templates>
</xsl:template>

<xsl:template match="IDRef" mode="Replace">
    <xsl:param name="Replacement"/>
    <IDRef>
        <xsl:value-of select="$Replacement"/>
    </IDRef>
</xsl:template>

<xsl:template match="@* | node()">
    <xsl:copy>
        <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
</xsl:template>
</xsl:stylesheet>

Answer 1

How about:

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:key name="id" match="ID" use="." />

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="ID">
    <xsl:copy>
        <xsl:value-of select="count(preceding::ID) + 1" />
    </xsl:copy>
</xsl:template>

<xsl:template match="IDRef">
    <xsl:copy>
        <xsl:value-of select="count(key('id', .)/preceding::ID) + 1" />
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>

Applied to the following test input:

<root>
    <master>
        <ID>12345</ID>
    </master>
    <slave>
        <IDRef>12345</IDRef>
    </slave>
    <element>
        <slave>
            <IDRef>987</IDRef>
        </slave>
    </element>
    <master>
        <ID>987</ID>
    </master>
    <slave>
        <IDRef>987</IDRef>
    </slave>
    <element>
        <slave>
            <IDRef>12345</IDRef>
        </slave>
    </element>
</root>

the result is:

<?xml version="1.0" encoding="UTF-8"?>
<root>
   <master>
      <ID>1</ID>
   </master>
   <slave>
      <IDRef>1</IDRef>
   </slave>
   <element>
      <slave>
         <IDRef>2</IDRef>
      </slave>
   </element>
   <master>
      <ID>2</ID>
   </master>
   <slave>
      <IDRef>2</IDRef>
   </slave>
   <element>
      <slave>
         <IDRef>1</IDRef>
      </slave>
   </element>
</root>

--
BTW, I don't quite see what purpose the shortening of ID values serves; as long as they are unique, who cares how long they are?

---

I am more concerned with how to (if it is possible): 1. match an ID tag, change its text node to a new value, 2. then match any IDRef nodes and replace their text with the same value as what was added to the ID tag in step 1

Well, it really depends on how exactly step 1 is performed. Because the IDRef can always get to the original ID element in the source document - but not to its transformed counterpart in the result tree.