使用XSLT 1.0在特定标记的位置拆分XML，并在整个结果中维护HTML标记

Question

I need to transform the following XML by splitting at the <hr/> tag. The content on either side of the split should then be stored as params, and output within separate divs.

I'm running into several issues:

1) I can't seem to use the <hr/> tag as the separator for this. I assume that's due to the parser stripping the tag prior to setting the new params? Is there a workaround for this? I do have control over the XML output within the <bodyText> node, and while I could use a specified string instead, the <hr/> tag makes for a more reliable flag maintenance-wise.

2) While <xsl:copy-of select="$desc"/> produces the full contents with HTML markup intact (which I need), $shortDesc and $longDesc both return the bare / stripped text content. How can I retain the HTML markup?

Essentially I need to split the XML at the point of the <hr/> tag, and then copy the before and after contents into separate divs with markup intact.

I've seen a few posts with challenges quite close to this, but each just different enough that I've been unable to resolve.

The XML:

<bodyText>
  <p>Lorem Ipsum Short</p>
  <hr/>
  <p>Lorem Ipsum Long</p>
</bodyText>

*And please note that the XML feed is admin-generated, so this is just a basic example. The actual feed is not dependable, only that there will be an <hr/> for where the split should occur.

The XSL:

<xsl:template name="ExpandContent_main">    
  <xsl:param name="desc" select="/bodyText"/>
  <xsl:param name="separator" select="'<hr/>'"/>
  <xsl:param name="shortDesc" select="substring-before($desc, $separator)"/>
  <xsl:param name="longDesc" select="substring-after($desc, $separator)"/>
  <div class="short-description">
    <xsl:copy-of select="$shortDesc"/>
  </div>
  <div class="long-description">
    <xsl:copy-of select="$longDesc"/>
  </div>
</xsl:template>

The expected output:

<div class="short-description">
  <p>Lorem Ipsum Short</p>
</div>
<div class="long-description">
  <p>Lorem Ipsum Long</p>
</div>

Answer 1

Your mistake is that you are trying to use string functions on nodes. Now, I don't think you need a named template for this. Consider the following stylesheet:

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="bodyText">
    <div class="short-description">
        <xsl:apply-templates select="p[not(preceding-sibling::hr)]"/>
    </div>
    <div class="long-description">
        <xsl:apply-templates select="p[preceding-sibling::hr]"/>
    </div>
 </xsl:template>

</xsl:stylesheet>

When applied to the following test input:

<content>
    <bodyText>
        <p>Lorem <i>Ipsum</i> Short</p>
        <hr/>
        <p>Lorem <b>Ipsum</b> Long</p>
    </bodyText>
</content>

the result will be:

<?xml version="1.0" encoding="UTF-8"?>
<content>
   <div class="short-description">
      <p>Lorem <i>Ipsum</i> Short</p>
   </div>
   <div class="long-description">
      <p>Lorem <b>Ipsum</b> Long</p>
   </div>
</content>

Answer 2

<xsl:template match="bodyText"> <div class="short-description"> <xsl:copy-of select="node()[following-sibling::hr]"/> </div> <div class="long-description"> <xsl:copy-of select="node()[preceding-sibling::hr]"/> </div> </xsl:template>