awk再加一列是第三列等于字符串

Question

I have a VCF file (tab delimited) where some "RPB" values went missing in the 2nd column and it sort of shifted the whole line to the left.

I have the following:

1   AF1=23  AC1=23
2   RPB=123 AF1=23  AC1=23
3   AF1=23  AC1=23

I need the following:

1   NULL    AF1=23  AC1=23
2   RPB=123 AF1=23  AC1=23
3   NULL    AF1=23  AC1=23

I tried that, it worked miserably..:

awk 'if($2="AF1%" {print $1,"\t"NULL"\t", print$2, print$3}' input.vcf > output.vcf

I have to import this VCF to MySQL so the tab delimitation has to be conserved .. any idea?

Answer 1

$ awk 'NF<4{sub(/\t/,"&NULL&")}1' file
1       NULL    AF1=23  AC1=23
2       RPB=123 AF1=23  AC1=23
3       NULL    AF1=23  AC1=23

By the way, you weren't TOO far off a functional solution with your attempt:

awk 'if($2="AF1%" {print $1,"\t"NULL"\t", print$2, print$3}' input.vcf

This minimally altered version would have produced the output you want:

awk '{if($2~/^AF1/) print $1 "\tNULL\t" $2 "\t" $3; else print}' input.vcf

but as you can see that's not a very idiomatic approach.

Answer 2

this awk one-liner would help you:

kent$  awk -F'\t' -v OFS='\t' '!($2~/^RPB=/){$2="NULL\t"$2}7' file
1       NULL    AF1=23  AC1=23
2       RPB=123 AF1=23  AC1=23
3       NULL    AF1=23  AC1=23

Answer 3

IMHO you shouldn't use regex, Try this:

#!/bin/bash
cat input.vcf |\
perl -ane '
    BEGIN{$c=0;$max_fields=0}
    $c2=0;
    foreach(@F){
        $a[$c][$c2]=$_;
        if( $c2  > $max_fields ) {
            $max_fields=$c2; 
        }
        $c2++
    }
    $c++;
    END{
        foreach $i (@a){
            while (@$i < $max_fields + 1 ){
                unshift (@$i,"NULL");   
            }  
        }
        foreach $i (@a){
            foreach $x (@$i){
                print $x,"\t";
            }
            print "\n";
        }
    }'

Output:

bash test.sh 
NULL    AF1=23  AC1=23  
RPB=123 AF1=23  AC1=23  
NULL    AF1=23  AC1=23  

Explanation:

1. The code above creates a 2D array (row/fields)
2. It also stores max_fields
3. for each row, if number of fields is less than max_fields than insert "NULL" a the beginnig of the row

Answer 4

Based on a tab delimited input file:

awk -v OFS="\t" 'NF==3{$1=$1 OFS "NULL"} 1' input.vcf

where it could be altered to the following if the input file isn't tab delimited:

awk -v OFS="\t" '{$1=$1 (NF==3 ? OFS "NULL" : "")} 1' input.vcf

In either, when NF==3 the first field is re-assigned to contain the missing data. In the first example, only the output delimiters of the altered lines need adjusting, but when the data isn't tab delimited, each line needs to be "re-computed" with re-assignment prior to the 1 which is printing the whole line.

The beauty of Ed's answer when the input file is tab delimited is that the whole line output delimiter isn't "re-computed" when the substitution takes place, because it's the first delimiter that's being replaced.